রঙের প্যালেট

মেমরি

সাধারণত অপারেটিং সিস্টেম (OS) একটি প্রোগ্রামের জন্য মেমরিকে একটি সাধারণ বিন্যাসে সাজিয়ে দেয়:

সেগমেন্টে ভাগ করা মেমরি আবার সেকশনগুলোতে সাজানো থাকে, আর প্রতিটি সেকশনের অনুমতিও আলাদা।

এখন পর্যন্ত আমরা যে ফাংশনগুলো ডিফাইন করেছি, সেগুলো সবই ছিল section .text-এ। এই সেকশনে থাকে রিড-ওনলি এক্সিকিউটেবল ডেটা। অন্য সেকশনগুলো ব্যবহার করা হয় ডেটা ভ্যারিয়েবল ডিক্লেয়ার করার জন্য; এগুলো রিড-ওনলি বা রিড-অ্যান্ড-রাইট হতে পারে, কিন্তু এক্সিকিউটেবল নয়।

Section .data

ইনিশিয়ালাইজড ডেটা ডিক্লেয়ার করা হয় section .data-এ।

NASM-এ (The Netwide Assembler, এই ট্র্যাকের অ্যাসেম্বলার), একটি ইনিশিয়ালাইজড ভ্যারিয়েবলের থাকে একটি নাম, ডেটার সাইজ বোঝানো একটি ডিরেক্টিভ, আর কমা দিয়ে আলাদা করা মানের একটি তালিকা। এগুলোর প্রতিটিকে একটি স্পেস দিয়ে আলাদা করা হয়, আর লেবেলের পরে চাইলে একটি : থাকতে পারে।

প্রধান ডিরেক্টিভগুলো এবং তাদের সংশ্লিষ্ট ডেটা সাইজ:

যেমন, এটি space নামের একটি বাইট ভ্যারিয়েবল ডিক্লেয়ার করে যার মান 10:

section .data
    space db 10

section .data-এ ডিক্লেয়ার করা ভ্যারিয়েবলগুলো মিউটেবল, অর্থাৎ এগুলো রিড-অ্যান্ড-রাইট। এগুলোর স্টোরেজ ডিউরেশনও স্ট্যাটিক, অর্থাৎ প্রোগ্রাম চালু থাকার পুরো সময় জুড়ে এগুলো থাকে।

Section .rodata

section .rodata অনেকটা section .data-এর মতো। দুটি সেকশনেই ইনিশিয়ালাইজড ডেটা থাকে, যেগুলো একইভাবে ডিক্লেয়ার করা হয় এবং যাদের স্টোরেজ ডিউরেশনও একই।

এদের মধ্যে প্রধান পার্থক্য হলো section .rodata-এর ডেটা ইমিউটেবল, অর্থাৎ রিড-ওনলি।

ডেটা অ্যাক্সেস করা

লেবেল ও ইনডিরেকশন

ডিক্লেয়ার করা ডেটার সাথে একটি নাম যুক্ত থাকতে হয়। এই নামটিকে বলা হয় লেবেল।

লেবেল হলো একটি সিম্বল, যা মেমরিতে ডেটার নির্দিষ্ট ঠিকানা এনকোড করে। x86-64-এ ঠিকানা হলো ৬৪-বিট মান।

NASM-এ কোনো ডেটাকে সরাসরি তার লেবেল দিয়ে অ্যাক্সেস করতে গেলে বরাদ্দ করা মেমরি পাওয়া যায় না, বরং পাওয়া যায় তার ঠিকানা:

section .data
    example dq 27 ; this declares a 8-byte variable initialized with 27

section .text
fn:
    mov rax, example ; this stores the address of the declared variable in rax, not its contents
    ...

মেমরি ঠিকানার ভেতরের কনটেন্ট অ্যাক্সেস করতে হলে সেটিকে ডিরেফারেন্স করতে হয়। এটিকে বলা হয় ইনডিরেকশন।

NASM-এ এটি করা হয় [] দিয়ে:

section .data
    example dq -27 ; this declares a 8-byte variable initialized with -27

section .text
fn:
    mov rax, [example] ; this dereferences example and access the value stored in memory (-27)
    ...

তবে এমন কিছু পরিস্থিতি আছে, যেখানে ডিরেফারেন্স করা মেমরির সাইজ নিয়ে অস্পষ্টতা তৈরি হতে পারে। সেসব ক্ষেত্রে এই সাইজ উল্লেখ করে একটি প্রিফিক্স ব্যবহার করতে হয়।

একটি সাধারণ x86-64 প্রোগ্রামে সবচেয়ে গুরুত্বপূর্ণ প্রিফিক্সগুলো এবং তাদের সাইজ:

একই লোড সাইজ স্পষ্টভাবে উল্লেখ করেও লেখা যায়:

    mov rax, qword [example] ; same dereference, size stated explicitly

মেমরি ডিরেফারেন্স করার সময় সবসময় একটি প্রিফিক্স ব্যবহার করা ভালো অভ্যাস।

মেমরিতে লেখা

মেমরিতে লেখাও একইভাবে করা হয়, একটি ঠিকানা ডিরেফারেন্স করে:

section .data
    example1 db 10            ; example1 is a 1-byte memory location initialized with value 10
    example2 dq -456          ; example2 is a 8-byte memory location initialized with value -456
    example3 dd 54            ; example3 is a 4-byte memory location initialized with value 54

section .text
fn:
    mov byte [example1], 20   ; example1 now has value 20
    mov qword [example2], rdx ; example2 now has value equal to the contents in rdx
    mov dword [example3], eax ; example3 now has value equal to the contents in eax

মনে রাখবেন, বেশিরভাগ ইনস্ট্রাকশনে আগে রেজিস্টারে কনটেন্ট লোড না করেই আপনি মেমরি অপারেন্ড ব্যবহার করতে পারেন। তবে সাধারণত সোর্স ও ডেস্টিনেশন, দুটি অপারেন্ডেই একসাথে এগুলো ব্যবহার করা যায় না, দুটির মধ্যে কেবল একটি ব্যবহার করা যায়:

section .data
    example4 dw 4
    example5 dq -8
    example6 dd 15

section .text
fn:
    add word [example4], 5     ; example4 is now a 2-byte memory location with the value 4 + 5 = 9
    imul rax, qword [example5] ; rax = rax * (-8)
    ; this is not possible -> sub dword [example6], dword [example6]

LEA ইনস্ট্রাকশন

যদিও একটি ভ্যারিয়েবলের ঠিকানা রেজিস্টারে রাখতে mov ব্যবহার করা যায়, এর জন্য বিশেষভাবে তৈরি একটি ইনস্ট্রাকশনও আছে: lea।

এই ইনস্ট্রাকশন একটি মেমরি-ফর্ম অপারেন্ড ব্যবহার করে, কিন্তু এটি মেমরি পড়ে না। বরং এটি ইফেক্টিভ অ্যাড্রেস এক্সপ্রেশনটি হিসাব করে ফলাফলটি ডেস্টিনেশন অপারেন্ডে লেখে:

lea rax, [example] ; this stores the address of 'example' in rax

মেমরি ঠিকানা হিসাব করে রেজিস্টারে রাখতে lea ব্যবহার করাই বেশি স্বাভাবিক।

রিলেটিভ অ্যাড্রেসিং

মেমরি লোকেশন অ্যাক্সেস করার সময় NASM-এর ডিফল্ট আচরণ হলো অ্যাবসোলিউট অ্যাড্রেস তৈরি করা, অর্থাৎ নির্দিষ্ট মেমরি ঠিকানা।

নিরাপত্তার কারণে এক্সিকিউটেবল অনেক সময় PIE (Position Independent Executable) হিসেবে বিল্ড করা হয়, যেখানে মেমরি অঞ্চলগুলো এলোমেলো ঠিকানায় বসানো হয়। একটি PIE-তে লিংকের সময় কোনো ভ্যারিয়েবলের চূড়ান্ত ঠিকানা জানা থাকে না। তাই কোড বরং rip নামের একটি বিশেষ রেজিস্টারের মান থেকে অফসেট হিসেবে ঠিকানা হিসাব করে; rip পরের যে ইনস্ট্রাকশনটি এক্সিকিউট হবে সেটির দিকে ইঙ্গিত করে।

এটিকেই সাধারণত RIP-রিলেটিভ অ্যাড্রেসিং বলা হয়।

NASM-এ rel অপারেটর দিয়ে আপনি RIP-রিলেটিভ অ্যাক্সেস চাইতে পারেন:

mov rax, qword [rel variable]

সোর্স ফাইলের একেবারে উপরে default rel লিখে রিলেটিভ অ্যাড্রেসিংকে ডিফল্টও বানানো যায়।

এই ট্র্যাকের সব অনুশীলনী PIE হিসেবে কম্পাইল ও লিংক করা হয়, তাই রিলেটিভ ঠিকানা তৈরি করতে rel ব্যবহার করা উচিত।

ভিজিবিলিটি

যেকোনো সেকশনে (যেমন .text, .data, .rodata) ডিফাইন করা লেবেল (ফাংশন ও ডেটা) একই সোর্স ফাইলের ভেতরে দৃশ্যমান থাকে। যদি global ডিক্লেয়ার করা হয়, তবে সেগুলো অন্য সোর্স ফাইল থেকেও দৃশ্যমান থাকে।

উল্টোদিকে, অন্য সোর্স ফাইলে ডিফাইন করা লেবেল extern ডিক্লেয়ার করা থাকলে বর্তমান সোর্স ফাইলে দৃশ্যমান থাকে। এক্ষেত্রে অ্যাসেম্বলিতে ডেটার সাইজের কোনো ইঙ্গিত থাকে না, এটি আগে থেকেই জানা থাকতে হয়।

default rel

section .data

global number1 ; 'number1' is a variable visible to other source files
number1 db 200

extern number2 ; 'number2' is a variable visible to the current source file, but defined in another

section .text

extern sum ; sum is a function visible to the current source file, but defined in another

fn:
    mov dil, byte [number1]
    mov sil, byte [number2]
    call sum
    ...