Paleta de colores

Memoria

Por lo general, el sistema operativo (SO) mapea la memoria de un programa con una distribución general:

La memoria en segmentos se organiza en secciones, con diferentes permisos.

Las funciones que hemos definido hasta ahora estaban todas en la sección .text. Esta sección contiene datos ejecutables de solo lectura. Otras secciones se usan para declarar variables de datos, que pueden ser de solo lectura o de lectura y escritura, pero no son ejecutables.

Sección .data

Los datos inicializados se declaran en la sección .data.

En NASM (The Netwide Assembler, el ensamblador que usa este track), una variable inicializada tiene un nombre, una directiva que indica el tamaño de los datos y una lista de valores separados por comas. Cada uno de estos se separa del siguiente con un espacio, y la etiqueta puede ir opcionalmente seguida de :.

Las directivas principales y sus tamaños de datos correspondientes son:

Por ejemplo, esto declara una variable de un byte llamada space con el valor 10:

section .data
    space db 10

Las variables declaradas en section .data son mutables, es decir, son de lectura y escritura. También tienen una duración de almacenamiento estática, lo que significa que existen durante toda la ejecución del programa.

Sección .rodata

La sección .rodata es similar a section .data. Ambas secciones contienen datos inicializados, que se declaran de la misma manera y tienen la misma duración de almacenamiento.

La principal diferencia entre ellas es que los datos en section .rodata son inmutables, es decir, de solo lectura.

Acceder a los datos

Etiquetas e indirección

Los datos declarados deben tener un nombre asociado. Ese nombre se llama etiqueta.

Una etiqueta es un símbolo que codifica la dirección específica de los datos en memoria. Las direcciones en x86-64 son valores de 64 bits.

En NASM, intentar acceder a los datos directamente con su etiqueta no da como resultado la memoria asignada, sino su dirección:

section .data
    example dq 27 ; this declares a 8-byte variable initialized with 27

section .text
fn:
    mov rax, example ; this stores the address of the declared variable in rax, not its contents
    ...

Para acceder al contenido de una dirección de memoria, es necesario desreferenciarla. Esto se llama indirección.

En NASM, esto se hace con []:

section .data
    example dq -27 ; this declares a 8-byte variable initialized with -27

section .text
fn:
    mov rax, [example] ; this dereferences example and access the value stored in memory (-27)
    ...

Sin embargo, hay algunas situaciones en las que puede haber ambigüedad respecto al tamaño de la memoria desreferenciada. En esos casos, se debe usar un prefijo que especifique ese tamaño.

Estos son los prefijos más importantes y sus tamaños en un programa típico de x86-64:

La misma carga se puede escribir con el tamaño indicado de forma explícita:

    mov rax, qword [example] ; same dereference, size stated explicitly

Es una buena práctica usar siempre un prefijo al desreferenciar memoria.

Escribir en memoria

Escribir en memoria se hace de la misma manera, desreferenciando una dirección:

section .data
    example1 db 10            ; example1 is a 1-byte memory location initialized with value 10
    example2 dq -456          ; example2 is a 8-byte memory location initialized with value -456
    example3 dd 54            ; example3 is a 4-byte memory location initialized with value 54

section .text
fn:
    mov byte [example1], 20   ; example1 now has value 20
    mov qword [example2], rdx ; example2 now has value equal to the contents in rdx
    mov dword [example3], eax ; example3 now has value equal to the contents in eax

Ten en cuenta que puedes usar operandos de memoria en la mayoría de las instrucciones sin cargar primero el contenido en un registro. Sin embargo, por lo general no es posible usarlos tanto en el operando de origen como en el de destino, solo en uno de los dos:

section .data
    example4 dw 4
    example5 dq -8
    example6 dd 15

section .text
fn:
    add word [example4], 5     ; example4 is now a 2-byte memory location with the value 4 + 5 = 9
    imul rax, qword [example5] ; rax = rax * (-8)
    ; this is not possible -> sub dword [example6], dword [example6]

La instrucción LEA

Aunque se puede usar mov para almacenar la dirección de una variable en un registro, existe una instrucción con este propósito específico: lea.

Esta instrucción usa un operando en forma de memoria, pero no lee la memoria. En su lugar, calcula la expresión de dirección efectiva y escribe el resultado en el operando de destino:

lea rax, [example] ; this stores the address of 'example' in rax

Es más idiomático usar lea para calcular y almacenar direcciones de memoria en registros.

Direccionamiento relativo

Al acceder a ubicaciones de memoria, el comportamiento predeterminado en NASM es generar direcciones absolutas, es decir, direcciones de memoria fijas.

Por razones de seguridad, los ejecutables a menudo se compilan como PIE (ejecutable independiente de la posición), donde las regiones de memoria se colocan en ubicaciones aleatorizadas. En un PIE, la dirección final de una variable no se conoce en el momento del enlace. Por eso, el código calcula las direcciones como un desplazamiento a partir del valor de un registro especial llamado rip, que apunta a la siguiente instrucción por ejecutar.

A esto se le suele llamar direccionamiento relativo a RIP.

En NASM puedes solicitar acceso relativo a RIP con el operador rel:

mov rax, qword [rel variable]

El direccionamiento relativo también se puede establecer como predeterminado para un archivo fuente con default rel al principio.

Todos los ejercicios de este track se compilan y enlazan como PIE, así que se debe usar rel para generar direcciones relativas.

Visibilidad

Las etiquetas (funciones y datos) definidas en cualquier sección (p. ej., .text, .data, .rodata) son visibles dentro del mismo archivo fuente. Si se declaran global, también son visibles para otros archivos fuente.

A la inversa, las etiquetas definidas en otros archivos fuente son visibles para el archivo fuente actual si se declaran extern. En este caso, no hay ninguna indicación del tamaño de los datos en el ensamblado; esto se debe conocer de antemano.

default rel

section .data

global number1 ; 'number1' is a variable visible to other source files
number1 db 200

extern number2 ; 'number2' is a variable visible to the current source file, but defined in another

section .text

extern sum ; sum is a function visible to the current source file, but defined in another

fn:
    mov dil, byte [number1]
    mov sil, byte [number2]
    call sum
    ...