カラーパレット

メモリ

メモリは通常、オペレーティングシステム（OS）によって、プログラムのために次のような一般的なレイアウトで割り当てられます。

セグメントに分けられたメモリは、それぞれ異なる権限を持つセクションに整理されています。

これまで定義してきた関数は、すべてSection .textにありました。 このセクションには、読み取り専用の実行可能なデータが格納されます。 ほかのセクションはデータ変数を宣言するために使われます。データ変数は読み取り専用の場合も読み書き可能な場合もありますが、実行可能ではありません。

Section .data

初期化されたデータは、Section .dataで宣言します。

NASM（The Netwide Assembler。このトラックで使うアセンブラーです）では、初期化された変数は、名前、データサイズを示すディレクティブ、カンマで区切られた値のリストからなります。 それぞれはスペースで区切られ、ラベルの後ろには必要に応じて:を付けられます。

主なディレクティブと、それに対応するデータサイズは次のとおりです。

たとえば、次のコードはspaceという名前のバイト変数を値10で宣言します。

section .data
    space db 10

section .dataで宣言した変数は可変、つまり読み書き可能です。 また、_静的_な記憶域期間を持ちます。これは、プログラムの実行中ずっと存在することを意味します。

Section .rodata

Section .rodataはsection .dataと似ています。 どちらのセクションも初期化されたデータを含み、同じ方法で宣言され、同じ記憶域期間を持ちます。

主な違いは、section .rodataのデータが不変、つまり読み取り専用であることです。

データへのアクセス

ラベルと間接参照

宣言したデータには、名前を関連付ける必要があります。 この名前をラベルと呼びます。

ラベルは、メモリ内のデータの特定のアドレスを表すシンボルです。 x86-64のアドレスは64ビットの値です。

NASMでは、ラベルを使ってデータに直接アクセスしようとしても、割り当てられたメモリそのものではなく、そのアドレスが得られます。

section .data
    example dq 27 ; this declares a 8-byte variable initialized with 27

section .text
fn:
    mov rax, example ; this stores the address of the declared variable in rax, not its contents
    ...

メモリアドレスの内容にアクセスするには、そのアドレスを_逆参照_する必要があります。 これを間接参照と呼びます。

NASMでは、[]を使って行います。

section .data
    example dq -27 ; this declares a 8-byte variable initialized with -27

section .text
fn:
    mov rax, [example] ; this dereferences example and access the value stored in memory (-27)
    ...

ただし、逆参照するメモリのサイズが曖昧になる状況もあります。 そのような場合は、サイズを指定するプレフィックスを使う必要があります。

一般的なx86-64プログラムで重要なプレフィックスとそのサイズは次のとおりです。

同じロードは、サイズを明示して書くこともできます。

    mov rax, qword [example] ; same dereference, size stated explicitly

メモリを逆参照するときは、常にプレフィックスを付けるのがよい習慣です。

メモリへの書き込み

メモリへの書き込みも同じ方法で、アドレスを逆参照して行います。

section .data
    example1 db 10            ; example1 is a 1-byte memory location initialized with value 10
    example2 dq -456          ; example2 is a 8-byte memory location initialized with value -456
    example3 dd 54            ; example3 is a 4-byte memory location initialized with value 54

section .text
fn:
    mov byte [example1], 20   ; example1 now has value 20
    mov qword [example2], rdx ; example2 now has value equal to the contents in rdx
    mov dword [example3], eax ; example3 now has value equal to the contents in eax

ほとんどの命令では、内容をレジスターに読み込まなくてもメモリオペランドを使えることに注意してください。 ただし、通常はソースとデスティネーションの両方のオペランドには使えず、どちらか一方だけに使えます。

section .data
    example4 dw 4
    example5 dq -8
    example6 dd 15

section .text
fn:
    add word [example4], 5     ; example4 is now a 2-byte memory location with the value 4 + 5 = 9
    imul rax, qword [example5] ; rax = rax * (-8)
    ; this is not possible -> sub dword [example6], dword [example6]

LEA命令

movを使って変数のアドレスをレジスターに格納することもできますが、この目的専用の命令があります。それがleaです。

この命令はメモリ形式のオペランドを使いますが、メモリを読み取ることは_ありません_。 代わりに、実効アドレスの式を計算し、その結果をデスティネーションオペランドに書き込みます。

lea rax, [example] ; this stores the address of 'example' in rax

メモリアドレスを計算してレジスターに格納するには、leaを使うほうがより自然です。

相対アドレス指定

メモリ位置にアクセスするとき、NASMのデフォルトの動作は絶対アドレス、つまり固定されたメモリアドレスを生成することです。

セキュリティ上の理由から、実行ファイルはしばしば**PIE（位置独立実行ファイル）**としてビルドされ、メモリ領域はランダムな位置に配置されます。 PIEでは、変数の最終的なアドレスはリンク時にわかりません。 そのため、コードはripという特別なレジスターの値からのオフセットとしてアドレスを計算します。ripは次に実行される命令を指します。

これは通常、RIP相対アドレス指定と呼ばれます。

NASMでは、rel演算子を使ってRIP相対アクセスを指定できます。

mov rax, qword [rel variable]

ファイルの先頭にdefault relと書けば、そのソースファイル全体で相対アドレス指定をデフォルトにできます。

このトラックのすべての演習はPIEとしてコンパイル・リンクされるので、相対アドレスを生成するにはrelを使うようにします。

可視性

どのセクション（たとえば.text、.data、.rodata）で定義したラベル（関数やデータ）も、同じソースファイル内から見えます。 globalで宣言すれば、ほかのソースファイルからも見えます。

逆に、ほかのソースファイルで定義したラベルは、externで宣言すれば現在のソースファイルから見えます。 この場合、アセンブリーにはデータサイズの記載がないため、あらかじめ把握しておく必要があります。

default rel

section .data

global number1 ; 'number1' is a variable visible to other source files
number1 db 200

extern number2 ; 'number2' is a variable visible to the current source file, but defined in another

section .text

extern sum ; sum is a function visible to the current source file, but defined in another

fn:
    mov dil, byte [number1]
    mov sil, byte [number2]
    call sum
    ...