Memória
A memóriát egy program számára általában az operációs rendszer (OS) képezi le egy általános elrendezés szerint:
| cím |
memóriaterület |
| magas |
verem |
|
... |
|
kupac |
|
olvasható-írható szegmens |
|
kód/csak olvasható szegmens |
| alacsony |
fenntartott |
A szegmensekre osztott memória különböző jogosultságú szakaszokra tagolódik.
Az eddig definiált függvényeink mind a .text szakaszban voltak.
Ez a szakasz csak olvasható, végrehajtható adatokat tartalmaz.
Más szakaszok adatváltozók deklarálására szolgálnak, amelyek lehetnek csak olvashatók vagy olvasható-írhatók, de nem végrehajthatók.
A .data szakasz
Az inicializált adatokat a .data szakaszban deklaráljuk.
A NASM-ben (The Netwide Assembler, az ezen a kurzuson használt assembler) egy inicializált változónak van neve, egy direktívája, amely az adat méretét jelzi, és egy vesszővel elválasztott értéklistája.
Ezeket szóköz választja el egymástól, a címkét pedig opcionálisan : követheti.
A fő direktívák és a hozzájuk tartozó adatméretek:
| direktíva |
méret |
| db |
1 bájt |
| dw |
2 bájt |
| dd |
4 bájt |
| dq |
8 bájt |
Például ez egy space nevű, 1 bájtos változót deklarál 10 értékkel:
section .data
space db 10
A section .data szakaszban deklarált változók módosíthatók, azaz olvashatók és írhatók.
Emellett statikus tárolási időtartammal rendelkeznek, ami azt jelenti, hogy a program teljes futamideje alatt léteznek.
A .rodata szakasz
A .rodata szakasz hasonló a section .data szakaszhoz.
Mindkét szakasz inicializált adatokat tartalmaz, amelyeket ugyanúgy deklarálunk, és amelyeknek ugyanaz a tárolási időtartama.
A fő különbség köztük az, hogy a section .rodata szakaszban lévő adatok változhatatlanok, azaz csak olvashatók.
Az equ direktívával definiált konstansok eltérnek a section .rodata szakaszban definiáltaktól.
Az equ direktívával definiált konstans nem foglal helyet a memóriában, és az assembler közvetlenül behelyettesíti az értékével.
Valójában ez csupán az adott érték helyőrzője.
Ezzel szemben a section .rodata szakaszban definiált konstansok ténylegesen a memóriában tárolódnak, és van címük.
Az adatok elérése
Címkék és indirekció
A deklarált adatokhoz névnek kell kapcsolódnia.
Ezt a nevet címkének nevezzük.
A címke egy szimbólum, amely a memóriában lévő adat konkrét címét kódolja.
Az x86-64-ben a címek 64 bites értékek.
A NASM-ben, ha egy adatot közvetlenül a címkéjével próbálunk elérni, nem a lefoglalt memóriát kapjuk meg, hanem annak címét:
section .data
example dq 27 ; this declares a 8-byte variable initialized with 27
section .text
fn:
mov rax, example ; this stores the address of the declared variable in rax, not its contents
...
Ahhoz, hogy egy memóriacím tartalmát elérjük, dereferálni kell azt.
Ezt indirekciónak nevezzük.
A NASM-ben erre a [] szolgál:
section .data
example dq -27 ; this declares a 8-byte variable initialized with -27
section .text
fn:
mov rax, [example] ; this dereferences example and access the value stored in memory (-27)
...
Vannak azonban olyan helyzetek, amikor kérdéses lehet a dereferált memória mérete.
Ilyen esetekben a méretet megadó előtagot kell használni.
Ezek a legfontosabb előtagok és méreteik egy tipikus x86-64 programban:
| előtag |
méret |
| byte |
1 bájt |
| word |
2 bájt |
| dword |
4 bájt |
| qword |
8 bájt |
Ugyanez a betöltés kiírható úgy is, hogy a méretet egyértelműen megadjuk:
mov rax, qword [example] ; same dereference, size stated explicitly
Jó gyakorlat, ha memória dereferálásakor mindig használunk előtagot.
Írás a memóriába
A memóriába írás ugyanígy történik, egy cím dereferálásával:
section .data
example1 db 10 ; example1 is a 1-byte memory location initialized with value 10
example2 dq -456 ; example2 is a 8-byte memory location initialized with value -456
example3 dd 54 ; example3 is a 4-byte memory location initialized with value 54
section .text
fn:
mov byte [example1], 20 ; example1 now has value 20
mov qword [example2], rdx ; example2 now has value equal to the contents in rdx
mov dword [example3], eax ; example3 now has value equal to the contents in eax
Megjegyzendő, hogy a legtöbb utasításban használhatsz memóriaoperandusokat anélkül, hogy előbb betöltenéd a tartalmukat egy regiszterbe.
Általában azonban nem lehet egyszerre a forrás- és a céloperandusban használni őket, csak az egyikben:
section .data
example4 dw 4
example5 dq -8
example6 dd 15
section .text
fn:
add word [example4], 5 ; example4 is now a 2-byte memory location with the value 4 + 5 = 9
imul rax, qword [example5] ; rax = rax * (-8)
; this is not possible -> sub dword [example6], dword [example6]
A LEA utasítás
Bár a mov is használható egy változó címének regiszterbe mentésére, erre a konkrét célra külön utasítás létezik: a lea.
Ez az utasítás memóriaformájú operandust használ, de nem olvassa a memóriát.
Ehelyett kiértékeli az effektív cím kifejezését, és az eredményt a céloperandusba írja:
lea rax, [example] ; this stores the address of 'example' in rax
Idiomatikusabb a lea utasítást használni memóriacímek kiszámítására és regiszterekbe mentésére.
Relatív címzés
Amikor memóriahelyeket érünk el, a NASM alapértelmezett viselkedése, hogy abszolút címeket, azaz rögzített memóriacímeket állít elő.
Biztonsági okokból a futtatható fájlokat gyakran PIE (pozíciófüggetlen futtatható fájl) formában készítik el, ahol a memóriaterületek véletlenszerűen kiválasztott helyekre kerülnek.
Egy PIE-ban egy változó végleges címe nem ismert a linkelés idején.
Ezért a kód inkább egy rip nevű speciális regiszter értékéhez viszonyított eltolásként számítja ki a címeket; ez a regiszter a végrehajtandó következő utasításra mutat.
Ezt általában RIP-relatív címzésnek nevezik.
A NASM-ben a rel operátorral kérhetsz RIP-relatív elérést:
mov rax, qword [rel variable]
A relatív címzés egy forrásfájl alapértelmezésévé is tehető a fájl elején szereplő default rel direktívával.
Ezen a kurzuson minden feladatot PIE-ként fordítunk és linkelünk, ezért a relatív címek előállításához a rel-t kell használni.
Láthatóság
Bármely szakaszban (például .text, .data, .rodata) definiált címke (függvény és adat) látható ugyanazon forrásfájlon belül.
Ha global-ként vannak deklarálva, más forrásfájlokból is láthatók.
Fordítva, a más forrásfájlokban definiált címkék akkor láthatók az aktuális forrásfájlból, ha extern-ként vannak deklarálva.
Ebben az esetben az assemblyben nincs utalás az adat méretére, azt előre ismerni kell.
default rel
section .data
global number1 ; 'number1' is a variable visible to other source files
number1 db 200
extern number2 ; 'number2' is a variable visible to the current source file, but defined in another
section .text
extern sum ; sum is a function visible to the current source file, but defined in another
fn:
mov dil, byte [number1]
mov sil, byte [number2]
call sum
...
Tanulófeladat
