색상 팔레트

메모리

프로그램의 메모리는 보통 운영체제(Operating System, OS)가 다음과 같은 일반적인 배치로 매핑해요:

세그먼트로 나뉜 메모리는 서로 다른 권한을 가진 섹션들로 구성돼요.

지금까지 정의한 함수는 모두 section .text에 있었어요. 이 섹션은 읽기 전용의 실행 가능한 데이터를 담아요. 다른 섹션은 데이터 변수를 선언하는 데 사용되는데, 읽기 전용일 수도 있고 읽기-쓰기가 가능할 수도 있지만 실행할 수는 없어요.

.data 섹션

초기화된 데이터는 section .data에 선언해요.

NASM(The Netwide Assembler, 이 트랙에서 사용하는 어셈블러)에서는 초기화된 변수가 이름, 데이터 크기를 나타내는 지시어, 그리고 쉼표로 구분된 값들의 목록으로 이루어져 있어요. 이 요소들은 서로 공백으로 구분하고, 레이블 뒤에는 선택적으로 :를 붙일 수 있어요.

주요 지시어와 그에 대응하는 데이터 크기는 다음과 같아요:

예를 들어, 다음은 space라는 이름의 바이트 변수를 값 10으로 선언해요:

section .data
    space db 10

section .data에 선언한 변수는 가변적이에요. 즉, 읽기-쓰기가 가능해요. 또한 정적 저장 기간을 가지는데, 이는 프로그램이 실행되는 동안 내내 존재한다는 뜻이에요.

.rodata 섹션

section .rodata는 section .data와 비슷해요. 두 섹션 모두 초기화된 데이터를 담고, 같은 방식으로 선언하며 저장 기간도 같아요.

둘의 가장 큰 차이는 section .rodata의 데이터가 불변이며, 즉 읽기 전용이라는 점이에요.

데이터 접근하기

레이블과 간접 참조

선언한 데이터에는 반드시 이름이 연결되어 있어야 해요. 이 이름을 레이블이라고 해요.

레이블은 메모리에서 데이터의 구체적인 주소를 나타내는 기호예요. x86-64에서 주소는 64비트 값이에요.

NASM에서는 레이블로 데이터에 직접 접근하려고 하면 할당된 메모리가 아니라 그 주소를 얻어요:

section .data
    example dq 27 ; this declares a 8-byte variable initialized with 27

section .text
fn:
    mov rax, example ; this stores the address of the declared variable in rax, not its contents
    ...

메모리 주소의 내용에 접근하려면 그것을 _역참조_해야 해요. 이것을 간접 참조라고 해요.

NASM에서는 []로 해요:

section .data
    example dq -27 ; this declares a 8-byte variable initialized with -27

section .text
fn:
    mov rax, [example] ; this dereferences example and access the value stored in memory (-27)
    ...

그런데 역참조하는 메모리의 크기가 모호해질 수 있는 상황도 있어요. 그럴 때는 이 크기를 지정하는 접두사를 사용해야 해요.

일반적인 x86-64 프로그램에서 가장 중요한 접두사와 그 크기는 다음과 같아요:

같은 로드를 크기를 명시해서 쓸 수도 있어요:

    mov rax, qword [example] ; same dereference, size stated explicitly

메모리를 역참조할 때는 항상 접두사를 사용하는 것이 좋아요.

메모리에 쓰기

메모리에 쓰는 것도 주소를 역참조하는 같은 방식으로 해요:

section .data
    example1 db 10            ; example1 is a 1-byte memory location initialized with value 10
    example2 dq -456          ; example2 is a 8-byte memory location initialized with value -456
    example3 dd 54            ; example3 is a 4-byte memory location initialized with value 54

section .text
fn:
    mov byte [example1], 20   ; example1 now has value 20
    mov qword [example2], rdx ; example2 now has value equal to the contents in rdx
    mov dword [example3], eax ; example3 now has value equal to the contents in eax

대부분의 명령어에서 내용을 먼저 레지스터에 로드하지 않고도 메모리 피연산자를 사용할 수 있다는 점을 기억해 둬요. 하지만 보통은 원본 피연산자와 목적지 피연산자 양쪽에 모두 사용할 수는 없고, 둘 중 하나에만 쓸 수 있어요:

section .data
    example4 dw 4
    example5 dq -8
    example6 dd 15

section .text
fn:
    add word [example4], 5     ; example4 is now a 2-byte memory location with the value 4 + 5 = 9
    imul rax, qword [example5] ; rax = rax * (-8)
    ; this is not possible -> sub dword [example6], dword [example6]

LEA 명령어

mov로도 변수의 주소를 레지스터에 저장할 수 있지만, 이 목적만을 위한 명령어가 있어요: lea.

이 명령어는 메모리 형식의 피연산자를 사용하지만, 메모리를 읽지는 않아요. 대신 유효 주소 식을 계산해서 그 결과를 목적지 피연산자에 써요:

lea rax, [example] ; this stores the address of 'example' in rax

메모리 주소를 계산해서 레지스터에 저장할 때는 lea를 사용하는 편이 더 자연스러워요.

상대 주소 지정

메모리 위치에 접근할 때 NASM의 기본 동작은 절대 주소, 즉 고정된 메모리 주소를 생성하는 거예요.

보안상의 이유로 실행 파일은 흔히 **PIE(Position Independent Executable)**로 빌드되는데, 이때 메모리 영역은 무작위로 정해진 위치에 놓여요. PIE에서는 링크할 때 변수의 최종 주소를 알 수 없어요. 그래서 코드는 다음에 실행할 명령어를 가리키는 rip라는 특별한 레지스터의 값으로부터의 오프셋으로 주소를 계산해요.

이것을 보통 RIP 상대 주소 지정이라고 해요.

NASM에서는 rel 연산자로 RIP 상대 접근을 요청할 수 있어요:

mov rax, qword [rel variable]

소스 파일 맨 위에 default rel을 두면 상대 주소 지정을 기본값으로 만들 수도 있어요.

이 트랙의 모든 연습 문제는 PIE로 컴파일하고 링크하기 때문에, 상대 주소를 생성하려면 rel을 사용해야 해요.

가시성

어떤 섹션(예: .text, .data, .rodata)에 정의한 레이블(함수와 데이터)이든 같은 소스 파일 안에서는 보여요. global로 선언하면 다른 소스 파일에서도 보여요.

반대로 다른 소스 파일에 정의한 레이블은 extern으로 선언하면 현재 소스 파일에서 볼 수 있어요. 이 경우 어셈블리에는 데이터 크기를 나타내는 표시가 없으니, 크기를 미리 알고 있어야 해요.

default rel

section .data

global number1 ; 'number1' is a variable visible to other source files
number1 db 200

extern number2 ; 'number2' is a variable visible to the current source file, but defined in another

section .text

extern sum ; sum is a function visible to the current source file, but defined in another

fn:
    mov dil, byte [number1]
    mov sil, byte [number2]
    call sum
    ...