نقطه‌های رقصان

use

«ماکرو»ی use به ما اجازه می‌دهد که ماژول خود را به‌سرعت با قابلیت‌هایی گسترش دهیم که ماژول دیگری فراهم می‌کند. وقتی ماژولی را use می‌کنیم، آن ماژول می‌تواند کدی را به ماژول ما تزریق کند؛ برای مثال می‌تواند توابعی تعریف کند، ماژول‌های دیگر را import یا alias کند، یا ویژگی‌های ماژول را تنظیم کند.

اگر تا به حال فایل‌های تست برخی از تمرین‌های Elixir را اینجا در Exercism نگاه کرده باشید، به احتمال زیاد متوجه شده‌اید که همه‌ی آن‌ها با use ExUnit.Case شروع می‌شوند. همین یک خط کد است که ماکروهای test و assert را در ماژول تست در دسترس قرار می‌دهد.

defmodule LasagnaTest do
  use ExUnit.Case

  test "expected minutes in oven" do
    assert Lasagna.expected_minutes_in_oven() === 40
  end
end

ماکروی __using__/1

اینکه دقیقاً وقتی ماژولی را use می‌کنید چه اتفاقی می‌افتد را ماکروی __using__/1 آن ماژول تعیین می‌کند. این ماکرو یک آرگومان می‌گیرد، یعنی یک لیست کلیدواژه‌ای همراه با گزینه‌ها، و یک عبارت نقل‌قول‌شده برمی‌گرداند. کد موجود در این عبارت نقل‌قول‌شده هنگام فراخوانی use در ماژول ما درج می‌شود.

defmodule ExUnit.Case do
  defmacro __using__(opts) do
    # some real-life ExUnit code omitted here
    quote do
      import ExUnit.Assertions
      import ExUnit.Case, only: [describe: 2, test: 1, test: 2, test: 3]
    end
  end
end

گزینه‌ها را می‌توان هنگام فراخوانی use به‌عنوان آرگومان دوم ارائه داد، مثلاً use ExUnit.Case, async: true. اگر به‌صراحت داده نشوند، مقدار پیش‌فرضشان یک لیست خالی است.

رفتارها

«رفتارها» به ما اجازه می‌دهند که «رابط‌هایی» (مجموعه‌هایی از توابع و ماکروها) را در یک ماژول رفتار تعریف کنیم که بعداً می‌توانند توسط ماژول‌های فراخوان بازگشتی مختلف پیاده‌سازی شوند. به لطف رابط مشترک، می‌توان از آن ماژول‌های فراخوان بازگشتی به‌جای یکدیگر استفاده کرد.

تعریف رفتارها

برای تعریف یک رفتار، باید ماژول جدیدی بسازیم و فهرستی از توابعی را مشخص کنیم که بخشی از رابط موردنظر هستند. هر تابع باید با استفاده از ویژگی ماژول @callback تعریف شود. نحوه‌ی نگارش آن دقیقاً مانند یک مشخصات نوع تابع (@spec) است. باید اسم تابع، فهرستی از انواع آرگومان‌ها، و همه‌ی انواع بازگشتی ممکن را مشخص کنیم.

defmodule Countable do
  @callback count(collection :: any) :: pos_integer
end

پیاده‌سازی رفتارها

برای افزودن یک رفتار موجود به ماژول خود (ساخت یک ماژول فراخوان بازگشتی) از ویژگی ماژول @behaviour استفاده می‌کنیم. مقدار آن باید اسم ماژول رفتاری باشد که در حال افزودن آن هستیم.

سپس باید همه‌ی توابع (فراخوان‌های بازگشتی) موردنیاز آن ماژول رفتاری را تعریف کنیم. اگر در حال پیاده‌سازی رفتار شخص دیگری باشیم، مانند رفتارهای داخلی Access یا GenServer در Elixir، فهرست همه‌ی فراخوان‌های بازگشتی آن رفتار را در مستندات hexdocs.pm پیدا می‌کنیم.

یک ماژول فراخوان بازگشتی محدود به پیاده‌سازی فقط توابعی نیست که بخشی از رفتارش هستند. همچنین امکان دارد که یک ماژول واحد چندین رفتار را پیاده‌سازی کند.

برای مشخص‌کردن اینکه هر تابع از کدام رفتار می‌آید، باید ویژگی ماژول @impl را پیش از هر تابع به کار ببریم. مقدار آن باید اسم ماژول رفتاری باشد که این فراخوان بازگشتی را تعریف می‌کند.

defmodule BookCollection do
  @behaviour Countable

  defstruct [:list, :owner]

  @impl Countable
  def count(collection) do
    Enum.count(collection.list)
  end

  def mark_as_read(collection, book) do
    # other function unrelated to the Countable behaviour
  end
end

پیاده‌سازی‌های پیش‌فرض فراخوان بازگشتی

هنگام تعریف یک رفتار، امکان ارائه‌ی یک پیاده‌سازی پیش‌فرض برای یک فراخوان بازگشتی وجود دارد. این پیاده‌سازی باید در عبارت نقل‌قول‌شده‌ی ماکروی __using__/1 تعریف شود. برای اینکه کاربران ماژول رفتاری بتوانند پیاده‌سازی پیش‌فرض را بازنویسی کنند، ماکروی defoverridable/1 را پس از پیاده‌سازی تابع فراخوانی کنید. این ماکرو یک لیست کلیدواژه‌ای می‌پذیرد که اسم توابع به‌عنوان کلید و تعداد آرگومان‌های توابع به‌عنوان مقدار در آن قرار دارند.

defmodule Countable do
  @callback count(collection :: any) :: pos_integer

  defmacro __using__(_) do
    quote do
      @behaviour Countable
      def count(collection), do: Enum.count(collection)
      defoverridable count: 1
    end
  end
end

توجه داشته باشید که تعریف توابع درون __using__/1 برای هر هدفی جز تعریف پیاده‌سازی‌های پیش‌فرض فراخوان بازگشتی توصیه نمی‌شود، اما همیشه می‌توانید توابع را در ماژولی دیگر تعریف کنید و آن‌ها را در ماکروی __using__/1 import کنید.