नाचते बिंदु

use

use मैक्रो की मदद से हम किसी दूसरे मॉड्यूल की दी हुई सुविधाएँ अपने मॉड्यूल में जल्दी से जोड़ सकते हैं। जब हम किसी मॉड्यूल को use करते हैं, तो वह मॉड्यूल हमारे मॉड्यूल में कोड डाल सकता है। उदाहरण के लिए, वह फंक्शन परिभाषित कर सकता है, दूसरे मॉड्यूलों को import या alias कर सकता है, या मॉड्यूल एट्रिब्यूट सेट कर सकता है।

अगर आपने कभी यहाँ Exercism पर Elixir के कुछ अभ्यासों की टेस्ट फाइलें देखी हैं, तो आपने ज़रूर देखा होगा कि वे सब use ExUnit.Case से शुरू होती हैं। कोड की यही एक लाइन टेस्ट मॉड्यूल में test और assert मैक्रो उपलब्ध कराती है।

defmodule LasagnaTest do
  use ExUnit.Case

  test "expected minutes in oven" do
    assert Lasagna.expected_minutes_in_oven() === 40
  end
end

__using__/1 मैक्रो

जब आप किसी मॉड्यूल को use करते हैं, तो ठीक-ठीक क्या होता है, यह उस मॉड्यूल का __using__/1 मैक्रो तय करता है। यह एक आर्गुमेंट लेता है, जो विकल्पों वाली एक कीवर्ड लिस्ट होती है, और एक कोटेड एक्सप्रेशन लौटाता है। use कॉल करने पर इस कोटेड एक्सप्रेशन का कोड हमारे मॉड्यूल में जोड़ दिया जाता है।

defmodule ExUnit.Case do
  defmacro __using__(opts) do
    # some real-life ExUnit code omitted here
    quote do
      import ExUnit.Assertions
      import ExUnit.Case, only: [describe: 2, test: 1, test: 2, test: 3]
    end
  end
end

use कॉल करते समय विकल्प दूसरे आर्गुमेंट के रूप में भी दिए जा सकते हैं, जैसे use ExUnit.Case, async: true। जब ये स्पष्ट रूप से न दिए जाएँ, तो इन्हें खाली लिस्ट मान लिया जाता है।

बिहेवियर

बिहेवियर की मदद से हम किसी बिहेवियर मॉड्यूल में इंटरफ़ेस (फंक्शन और मैक्रो के समूह) परिभाषित कर सकते हैं, जिन्हें बाद में अलग-अलग कॉलबैक मॉड्यूल कार्यान्वित करते हैं। साझा इंटरफ़ेस की वजह से उन कॉलबैक मॉड्यूलों को एक-दूसरे की जगह इस्तेमाल किया जा सकता है।

बिहेवियर परिभाषित करना

बिहेवियर परिभाषित करने के लिए हमें एक नया मॉड्यूल बनाना होता है और उन सारे फंक्शनों की एक लिस्ट देनी होती है जो हमारे चाहे गए इंटरफ़ेस का हिस्सा हैं। हर फंक्शन को @callback मॉड्यूल एट्रिब्यूट की मदद से परिभाषित करना होता है। इसका सिंटैक्स फंक्शन टाइपस्पेक (@spec) जैसा ही होता है। हमें फंक्शन का नाम, आर्गुमेंट टाइप की एक लिस्ट, और सभी संभावित रिटर्न टाइप बताने होते हैं।

defmodule Countable do
  @callback count(collection :: any) :: pos_integer
end

बिहेवियर कार्यान्वित करना

अपने मॉड्यूल में कोई मौजूदा बिहेवियर जोड़ने के लिए (यानी कॉलबैक मॉड्यूल बनाने के लिए) हम @behaviour मॉड्यूल एट्रिब्यूट इस्तेमाल करते हैं। इसकी वैल्यू उस बिहेवियर मॉड्यूल का नाम होनी चाहिए जिसे हम जोड़ रहे हैं।

इसके बाद हमें उन सारे फंक्शन (कॉलबैक) को परिभाषित करना होता है जो उस बिहेवियर मॉड्यूल के लिए ज़रूरी हैं। अगर हम किसी और का बिहेवियर कार्यान्वित कर रहे हैं, जैसे Elixir के बने-बनाए Access या GenServer बिहेवियर, तो उस बिहेवियर के सारे कॉलबैक की लिस्ट हमें hexdocs.pm की डॉक्युमेंटेशन में मिल जाएगी।

किसी कॉलबैक मॉड्यूल को सिर्फ़ उन्हीं फंक्शनों तक सीमित रहना ज़रूरी नहीं है जो उसके बिहेवियर का हिस्सा हैं। एक ही मॉड्यूल कई बिहेवियर भी कार्यान्वित कर सकता है।

यह बताने के लिए कि कौन-सा फंक्शन किस बिहेवियर से आता है, हमें हर फंक्शन से पहले @impl मॉड्यूल एट्रिब्यूट लगाना चाहिए। इसकी वैल्यू उस बिहेवियर मॉड्यूल का नाम होनी चाहिए जो यह कॉलबैक परिभाषित करता है।

defmodule BookCollection do
  @behaviour Countable

  defstruct [:list, :owner]

  @impl Countable
  def count(collection) do
    Enum.count(collection.list)
  end

  def mark_as_read(collection, book) do
    # other function unrelated to the Countable behaviour
  end
end

डिफ़ॉल्ट कॉलबैक कार्यान्वयन

बिहेवियर परिभाषित करते समय किसी कॉलबैक का डिफ़ॉल्ट कार्यान्वयन देना भी संभव है। यह कार्यान्वयन __using__/1 मैक्रो के कोटेड एक्सप्रेशन में परिभाषित करना चाहिए। ताकि बिहेवियर मॉड्यूल का इस्तेमाल करने वाले इस डिफ़ॉल्ट कार्यान्वयन को ओवरराइड कर सकें, फंक्शन के कार्यान्वयन के बाद defoverridable/1 मैक्रो कॉल कीजिए। यह एक कीवर्ड लिस्ट लेता है जिसमें की के रूप में फंक्शन के नाम और वैल्यू के रूप में फंक्शन की आर्टी होती हैं।

defmodule Countable do
  @callback count(collection :: any) :: pos_integer

  defmacro __using__(_) do
    quote do
      @behaviour Countable
      def count(collection), do: Enum.count(collection)
      defoverridable count: 1
    end
  end
end

ध्यान दीजिए कि डिफ़ॉल्ट कॉलबैक कार्यान्वयन बनाने के अलावा किसी और उद्देश्य के लिए __using__/1 के अंदर फंक्शन परिभाषित करना ठीक नहीं माना जाता, लेकिन आप हमेशा किसी दूसरे मॉड्यूल में फंक्शन परिभाषित करके उन्हें __using__/1 मैक्रो में import कर सकते हैं।