Танцюючі крапки

Використання

Макрос use дає нам змогу швидко розширити наш модуль функціональністю, яку надає інший модуль. Коли ми застосовуємо use до модуля, цей модуль може вставити код у наш модуль: наприклад, визначити функції, виконати import чи alias інших модулів або встановити атрибути модуля.

Якщо ми колись бачили тестові файли деяких вправ з Elixir тут, на Exercism, то, найімовірніше, помітили, що всі вони починаються з use ExUnit.Case. Саме цей один рядок коду робить макроси test і assert доступними в тестовому модулі.

defmodule LasagnaTest do
  use ExUnit.Case

  test "expected minutes in oven" do
    assert Lasagna.expected_minutes_in_oven() === 40
  end
end

Макрос __using__/1

Що саме відбувається, коли ми застосовуємо use до модуля, визначає макрос __using__/1 цього модуля. Він приймає один аргумент, список ключових слів з опціями, і повертає цитований вираз. Код із цього цитованого виразу вставляється в наш модуль під час виклику use.

defmodule ExUnit.Case do
  defmacro __using__(opts) do
    # some real-life ExUnit code omitted here
    quote do
      import ExUnit.Assertions
      import ExUnit.Case, only: [describe: 2, test: 1, test: 2, test: 3]
    end
  end
end

Опції можна передати другим аргументом під час виклику use, наприклад: use ExUnit.Case, async: true. Якщо їх не вказати явно, типовим значенням є порожній список.

Поведінки

Поведінки дають нам змогу визначати інтерфейси (набори функцій і макросів) у модулі поведінки, які згодом можуть реалізувати різні модулі-колбеки. Завдяки спільному інтерфейсу ці модулі-колбеки можна використовувати взаємозамінно.

Визначення поведінок

Щоб визначити поведінку, нам потрібно створити новий модуль і вказати список функцій, які входять до потрібного інтерфейсу. Кожну функцію потрібно визначити за допомогою атрибута модуля @callback. Синтаксис такий самий, як у специфікації типу функції (@spec). Потрібно вказати назву функції, список типів аргументів і всі можливі типи поверненого значення.

defmodule Countable do
  @callback count(collection :: any) :: pos_integer
end

Реалізація поведінок

Щоб додати наявну поведінку до нашого модуля (створити модуль-колбек), ми використовуємо атрибут модуля @behaviour. Його значенням має бути назва модуля поведінки, яку ми додаємо.

Потім нам потрібно визначити всі функції (колбеки), які вимагає цей модуль поведінки. Якщо ми реалізуємо чужу поведінку, наприклад вбудовані поведінки Elixir Access чи GenServer, список усіх колбеків цієї поведінки можна знайти в документації на hexdocs.pm.

Модуль-колбек не обмежений реалізацією лише тих функцій, що входять до його поведінки. Один модуль також може реалізовувати кілька поведінок.

Щоб позначити, яка функція з якої поведінки походить, варто використати атрибут модуля @impl перед кожною функцією. Його значенням має бути назва модуля поведінки, який визначає цей колбек.

defmodule BookCollection do
  @behaviour Countable

  defstruct [:list, :owner]

  @impl Countable
  def count(collection) do
    Enum.count(collection.list)
  end

  def mark_as_read(collection, book) do
    # other function unrelated to the Countable behaviour
  end
end

Типові реалізації колбеків

Визначаючи поведінку, можна надати типову реалізацію колбека. Цю реалізацію слід визначити в цитованому виразі макроса __using__/1. Щоб користувачі модуля поведінки могли перевизначити типову реалізацію, потрібно викликати макрос defoverridable/1 після реалізації функції. Він приймає список ключових слів, де ключі - назви функцій, а значення - арності функцій.

defmodule Countable do
  @callback count(collection :: any) :: pos_integer

  defmacro __using__(_) do
    quote do
      @behaviour Countable
      def count(collection), do: Enum.count(collection)
      defoverridable count: 1
    end
  end
end

Зауважмо, що визначати функції всередині __using__/1 не рекомендується для будь-чого, крім визначення типових реалізацій колбеків, але завжди можна визначити функції в іншому модулі та імпортувати їх у макросі __using__/1.