成績表

SIMD：マスクと条件

スカラーコードは、ある条件に応じて分岐するために、さまざまな命令が設定するフラグに頼ります。 しかし、パックされた値は、1つではなく多くの値を並列に表します。 1つの条件が、あるレーンでは成り立たず、別のレーンでは成り立つことがあります。

そのため、SIMDコードはデフォルトで_ブランチレス_です。

フラグに頼る代わりに、パック比較は通常、デスティネーションオペランドにマスクを生成します。 各レーンについて、比較は、条件が真のときはそのレーン全体を1で埋め、偽のときは0で埋めます。 符号付き整数として読むと、真のレーンは-1になり、偽のレーンは0になります。

このマスクは、その後、ビット演算と組み合わせて特定のレーンをフィルタリングできます。

パック比較

スカラーのcmpは、さまざまなフラグを同時に設定するために使われるという意味で汎用的です。 別の命令が、それらのフラグを消費して、分岐したり計算を行ったりできます。

しかし、パック比較は条件をチェックすると同時にマスクを計算するため、汎用的ではありません。 比較には、テストする正確な条件を与える必要があります。

これには2つの方法があります。

• 整数比較では、条件をサフィックスとして与えます。等価にはeq、より大きいにはgtです。 その他のバリエーションは、これらのいずれかの結果を組み合わせて作ります。
• 浮動小数点比較では、条件を即値にエンコードして与えます。 この即値の値が異なると、テストされる条件も異なります。

整数比較で特定の条件サフィックスを使う点を除けば、構文はすでに見てきたのと同じ構造に従います。

• 整数の場合、p + cmp + 条件 + サイズ（b、w、d、またはq）です。
• 浮動小数点の場合、cmp + p + サイズ（sまたはd）です。 条件は、追加のオペランドとして即値で渡します。

整数比較

すでに述べたように、整数比較には等価と「より大きい」の2種類しかありません。

movdqa  xmm0, [rel scores]
pcmpgtd xmm0, [rel threshold] ; lane i = 0xFFFFFFFF (-1) if scores[i] > threshold[i], else 0

より小さい比較を作るには、オペランドを入れ替えてgtを使います。つまりa < b == b > aです。

比較は符号付きであることに注意してください。 符号なし比較を行うには、両方のオペランドの最上位ビットを反転します。 これは、最上位ビットだけがセットされたマスクとのXORで行えます。

pxor xmm4, xmm4    ; xmm4 = all zeros
pcmpeqd xmm7, xmm7 ; xmm7 = all ones

浮動小数点比較

浮動小数点のレーンでは形が異なります。cmpps（64ビットレーンの場合はcmppd）という1つの命令を使い、条件は即値として指定します。

movaps xmm0, [rel readings]
cmpps  xmm0, [rel limits], 1 ; condition 1 is "less than": lane i = all ones if readings[i] < limits[i]

NASMには、正しい即値に対応する、覚えやすい擬似命令もあります。 以下ではすべて、pxのxはs（32ビット浮動小数点数）またはd（64ビット浮動小数点数）です。

マスクによる選択

マスクは、条件の結果をエンコードします。 これを使うと、その条件に従って、2組の値のどちらかをレーンごとに選べます。 マスクが真のレーンでは一方の値から、偽のレーンではもう一方の値から、そのレーンを取ります。

; result = (a AND mask) OR (b AND NOT mask)
movdqa xmm2, xmm0  ; xmm0 holds the mask, keep a copy
pand   xmm2, xmm3  ; xmm2 = a AND mask: lanes of a where mask is true
pandn  xmm0, xmm4  ; xmm0 = NOT mask AND b: lanes of b where mask is false
por    xmm2, xmm0  ; combine the two halves

ここではpandnの非対称性が役立ちます。マスクはデスティネーションに置かれ、否定され、1つの命令でbから選択します。

このパターンは、ブランチレス選択のパック形式です。 すべてのレーンが計算され、どの値が生き残るかを決めるのはマスクだけで、どこにもjccは現れません。

専用のブレンド命令

同じ選択を直接行う命令もあり、マスクレジスタから要素ごとに1ビットを読み取ります。 これらはブレンド命令と呼ばれます。

最初の命令は整数の構文に従い、残りの2つは浮動小数点の構文に従うことに注意してください。 しかし、これらの命令は生のバイトを選択するだけなので、どれも整数と浮動小数点の両方で使えます。

各要素について、ブレンド命令は、対応するマスク要素の最上位ビットがクリアならデスティネーションを保持し、セットされていればソースを取ります。 参照されるのはその最上位ビットだけであり、比較マスクはその条件を満たします。そのレーンはすべて1かすべて0だからです。 マスクレジスタは常にxmm0で、これは暗黙です。

movaps   xmm0, [rel mask]  ; the selecting mask must be in xmm0
movaps   xmm1, [rel b]     ; destination: kept where the mask bit is clear
blendvps xmm1, [rel a]     ; source: taken where the mask bit is set

また、pblendvbを使って、他の任意のサイズの比較マスクからレーンを選択することもできます。 真のレーンのバイトはすべて1なので、pblendvbはそれらをすべて選択します。

マスクからスカラーへ戻す

SIMDコードは強力ですが、スカラーコードの柔軟性の多くを欠いています。 多くの場面で、パックレジスタからスカラー命令の世界へ戻す必要があります。

movmsk命令の一族は、この2つの世界の橋渡しをします。 これらの命令は、各レーンの最上位ビットを汎用レジスタに取り出します。

比較のあとに使うと、セットされた各ビットが「真」のレーンを、クリアされた各ビットが「偽」のレーンを表します。 この結果は、その後、通常どおりスカラー命令で操作できます。 たとえば、popcntは一致した数を数え、tzcntは最初のものを探します。

汎用レジスタは32ビット幅でも64ビット幅でもかまいません。

ベクトル全体のテスト

スカラー命令testにはパック版もあり、それがptestです。

スカラーの対応命令と似ており、2つのオペランドの間でAND演算を行いますが、それらを変更しません。 testと違い、ptestはANDN演算も行い、最初のオペランドを否定します。

したがって、ptestはpandとpandnの非破壊版で、結果に応じてフラグを設定すると考えられます。 この2つの命令とほぼ同じように、ptestはSIMDレジスタ全体を1つのレーンとして扱うため、サイズプレフィックスを取りません。

AND演算の結果が0ならZFがセットされ、ANDN演算の結果が0ならCFがセットされます。 つまり、ptestはすべて1のマスクとすべて0のマスクの両方をチェックするのに使えます。

1. レジスタに対して自身でptestを使うと、そのレジスタがすべて0の場合にのみZFがセットされます。 これは、レジスタが0かどうかをチェックするために自身でtestを使うという、よくあるスカラーのイディオムを再現します。
2. レジスタに対してすべて1のマスクでptestを使うと、そのレジスタがすべて1の場合にのみCFがセットされます。 また、そのレジスタがすべて0の場合にのみZFをセットするので、両方のマスクを一度にチェックできます。

pxor    xmm0, xmm0   ; all zeros
pcmpeqb xmm1, xmm1   ; all ones
pcmpeqb xmm2, xmm2

ptest xmm0, xmm0     ; ZF set: a register against itself detects all zeros
ptest xmm0, xmm1     ; ZF set, CF clear: xmm0 is all zeros, not all ones
ptest xmm2, xmm1     ; CF is set only if xmm2 is all ones

ptestの結果は、通常どおり、分岐や、setccやcmovccのようなブランチレス命令で使えます。