Baú do Tesouro Seguro

Tipos opacos

Introdução

Os tipos opacos são uma técnica de encapsulamento em Elm. Há quem lhe chame também ocultação de informação, ou ocultação de detalhes de implementação. Também são comummente usados para impor validação, com o padrão Parse, dont validate. Por exemplo, podes ter um tipo opaco EmailAddress, que só pode conter endereços de email válidos (ao contrário de uma String, que pode conter qualquer coisa).

Criar um tipo opaco

Os tipos personalizados têm uma ou mais variantes, e o compilador gera automaticamente uma função para criar cada variante, usando o nome da variante. São a única forma de criar tipos personalizados. O compilador também permite a desestruturação destas variantes.

type Maybe a
    = Nothing --> Variant implies a 'Nothing' function, with type 'Maybe a', and destructuring of 'Nothing'
    | Just a  --> Variant implies a 'Just' function, with type 'a -> Maybe a', and destructuring of 'Just _'

Por predefinição, tudo isto é interno ao ficheiro / módulo, e usamos a palavra-chave exposing para escolher o que exportar. Para criar um tipo opaco, basta escolheres não exportar as variantes.

Quando fazes isto, quase sempre precisas de arranjar outra forma de criar e obter as variantes, expondo funções personalizadas. Estas funções personalizadas permitem-te aplicar alguma lógica ao criar e obter as variantes. Isto oculta os detalhes de implementação internos do módulo, e significa que podes alterar os detalhes de implementação tanto quanto quiseres, desde que as funções expostas se mantenham iguais.

Parse, don't validate

Provavelmente, a utilização mais comum dos tipos opacos é impor validação, com o padrão Parse, dont validate. Neste padrão, expões uma função que recebe uma entrada com menos estrutura / segurança de tipos do que queres, como uma String, e depois analisas isso para obter um tipo mais estruturado, como EmailAddress, devolvendo o tipo ou devolvendo um erro (normalmente Maybe ou Result).

Por exemplo, no código abaixo, só é possível aos módulos externos criar um tipo EmailAddress com a função parseEmailAddress, por isso, quando estás a trabalhar com o tipo EmailAddress, tens a certeza de que é válido.

module EmailAddress exposing ( EmailAddress, parseEmailAddress, getEmailAddress )

-- The `EmailAddress` custom type has one variant, also called `EmailAddress`
-- When a custom type has one variant, it is idiomatic to use the same name for both.
type EmailAddress = 
  EmailAddress String

-- create an EmailAddress variant
parseEmailAddress: String -> Maybe EmailAddress
parseEmailAddress candidateEmailAddress =   
  if isValidEmailAddress candidateEmailAddress then
    Just (EmailAddress candidateEmailAddress)
  else
    Nothing

-- get an EmailAddress variant
getEmailAddress: EmailAddress -> String
getEmailAddress ( EmailAddress  emailAdress ) =
  emailAdress

isValidEmailAddress: String -> bool
-- ...