宝箱

泛型

简介

泛型是一种支持代码复用的语言特性。 例如，要计算数组的长度，数组里装的是什么类型并不重要。 正因如此，length函数在类型签名中使用了泛型类型参数a。

length : List a -> Int

类型中的参数

当一个类型对另一个类型泛型时，我们为那个类型使用小写名称，并称之为类型参数。 常见的例子是List、Maybe和Result这些自定义类型。

-- Maybe is generic over the type a
type Maybe a
    = Nothing
    | Just a

someString : Maybe String
someString = Just "hello"

someInt : Maybe Int
someInt = Just 42

关于类型参数的名称，有一点很重要：它们可以由多个字符组成。 唯一的限制是，它们必须是小写名称。 因此，在有用的时候，我们倾向于给它们起描述性的名称。

一个类型可以对多个其他类型泛型，因而拥有多个类型参数。 这种情况下，每个独立的类型都会得到不同的小写名称。 相互独立并不妨碍它们成为同一个类型，只是让它们可以不同。

-- Result is generic over the types error and value
type Result error value
    = Ok value
    | Err error

记录类型别名也可以有类型参数，不过这种情况比较少见。

-- Event is generic over the type a
type alias Event a =
    { at : Time
    , data : a 
    }

函数中的类型参数

既然类型可以是泛型的，那么函数也可以。 可以编写处理泛型类型的函数，比如Maybe.withDefault。

withDefault : a -> Maybe a -> a
withDefault default maybe =
    case maybe of
      Just value -> value
      Nothing -> default

把其他函数作为形参接收的函数称为高阶函数，它们也可以是泛型的。

map : (a -> b) -> Maybe a -> Maybe b
map function maybe =
  case maybe of
    Just value ->
      Just (function value)

    Nothing ->
      Nothing