গুপ্তধনের সিন্দুক

জেনেরিক্স

ভূমিকা

জেনেরিক্স হলো একটি ভাষার বৈশিষ্ট্য যা Code রিইউজ সক্ষম করে। উদাহরণস্বরূপ, একটি অ্যারে কী টাইপ ধারণ করে তা তার দৈর্ঘ্য গণনা করার জন্য গুরুত্বপূর্ণ হওয়া উচিত নয়। একারণেই length ফাংশনটি তার টাইপ সিগনেচারে একটি জেনেরিক টাইপ প্যারামিটার a ব্যবহার করে।

length : List a -> Int

টাইপে প্যারামিটার

যখন একটি টাইপ অন্য একটি টাইপের উপর জেনেরিক হয়, তখন আমরা সেই অন্য টাইপের জন্য একটি ছোট হাতের অক্ষরের নাম ব্যবহার করি এবং এটিকে টাইপ প্যারামিটার বলি। সাধারণ উদাহরণ হলো List, Maybe এবং Result কাস্টম টাইপ।

-- Maybe is generic over the type a
type Maybe a
    = Nothing
    | Just a

someString : Maybe String
someString = Just "hello"

someInt : Maybe Int
someInt = Just 42

টাইপ প্যারামিটারের নাম সম্পর্কে একটি গুরুত্বপূর্ণ মন্তব্য হলো, এগুলো একাধিক অক্ষরের হতে পারে। একমাত্র শর্ত হলো এগুলো অবশ্যই ছোট হাতের অক্ষরের নাম হতে হবে। তাই, যখন উপযোগী হয়, আমরা তাদের বর্ণনামূলক নাম দিয়ে থাকি।

একটি টাইপ একাধিক অন্য টাইপের উপর জেনেরিক হতে পারে, এবং এভাবে একাধিক টাইপ প্যারামিটার থাকতে পারে। সেক্ষেত্রে, প্রতিটি স্বাধীন টাইপ একটি ভিন্ন ছোট হাতের অক্ষরের নাম পায়। স্বাধীন হওয়া তাদের একই টাইপ হওয়া থেকে বিরত করে না, এটি কেবল তাদের ভিন্ন হওয়া সক্ষম করে।

-- Result is generic over the types error and value
type Result error value
    = Ok value
    | Err error

রেকর্ড টাইপ অ্যালিয়াসেও টাইপ প্যারামিটার থাকতে পারে, যদিও এটি কম দেখা যায়।

-- Event is generic over the type a
type alias Event a =
    { at : Time
    , data : a 
    }

ফাংশনে টাইপ প্যারামিটার

যেহেতু টাইপ জেনেরিক হতে পারে, ফাংশনও হতে পারে। জেনেরিক টাইপ নিয়ে কাজ করে এমন ফাংশন লেখা যায়, যেমন Maybe.withDefault.

withDefault : a -> Maybe a -> a
withDefault default maybe =
    case maybe of
      Just value -> value
      Nothing -> default

যে ফাংশনগুলো অন্য ফাংশনকে প্যারামিটার হিসেবে নেয় তাদের হায়ার অর্ডার ফাংশন বলা হয়, এবং এগুলোও জেনেরিক হতে পারে।

map : (a -> b) -> Maybe a -> Maybe b
map function maybe =
  case maybe of
    Just value ->
      Just (function value)

    Nothing ->
      Nothing