صندوق گنج

جنریک

مقدمه

«جنریک» یک ویژگی زبانی است که امکان استفاده‌ی دوباره از کد را فراهم می‌کند. برای مثال، نباید مهم باشد که یک لیست چه نوعی را در خود نگه می‌دارد تا بتوان طول آن را محاسبه کرد. به همین دلیل است که تابع length در امضای نوع خود از یک پارامتر نوع جنریک به اسم a استفاده می‌کند.

length : List a -> Int

پارامترها در نوع‌ها

وقتی یک نوع نسبت به نوع دیگری جنریک است، برای آن نوع دیگر از یک اسم با حروف کوچک استفاده می‌کنیم و آن را «پارامتر نوع» می‌نامیم. مثال‌های رایج، نوع‌های سفارشی List، Maybe و Result هستند.

-- Maybe is generic over the type a
type Maybe a
    = Nothing
    | Just a

someString : Maybe String
someString = Just "hello"

someInt : Maybe Int
someInt = Just 42

یک نکته‌ی مهم درباره‌ی اسم پارامترهای نوع این است که می‌توانند بیش از یک کاراکتر داشته باشند. تنها محدودیت این است که باید اسم‌هایی با حروف کوچک باشند. به همین دلیل، هر جا مفید باشد، تمایل داریم اسم‌هایی توصیفی برایشان انتخاب کنیم.

یک نوع می‌تواند نسبت به چند نوع دیگر جنریک باشد و در نتیجه چندین پارامتر نوع داشته باشد. در آن صورت، هر نوع مستقل یک اسم متفاوت با حروف کوچک می‌گیرد. مستقل بودن مانع از آن نمی‌شود که آن‌ها نو‌ع یکسانی شوند، فقط به آن‌ها امکان می‌دهد متفاوت باشند.

-- Result is generic over the types error and value
type Result error value
    = Ok value
    | Err error

نام‌های مستعار نوع رکورد هم می‌توانند پارامتر نوع داشته باشند، هرچند این کار کمتر رایج است.

-- Event is generic over the type a
type alias Event a =
    { at : Time
    , data : a 
    }

پارامترهای نوع در توابع

از آنجا که نوع‌ها می‌توانند جنریک باشند، توابع هم می‌توانند جنریک باشند. می‌توان توابعی نوشت که با نوع‌های جنریک کار می‌کنند، مانند Maybe.withDefault.

withDefault : a -> Maybe a -> a
withDefault default maybe =
    case maybe of
      Just value -> value
      Nothing -> default

توابعی که توابع دیگر را به عنوان پارامتر می‌گیرند، توابع مرتبه‌بالا نامیده می‌شوند و این‌ها هم می‌توانند جنریک باشند.

map : (a -> b) -> Maybe a -> Maybe b
map function maybe =
  case maybe of
    Just value ->
      Just (function value)

    Nothing ->
      Nothing