صندوق الكنز

الأنواع العامة

مقدمة

الأنواع العامة ميزة لغوية تتيح إعادة استخدام الكود. على سبيل المثال، لا ينبغي أن يهمنا نوع ما تحمله المصفوفة حتى نحسب طولها. لهذا السبب تستخدم دالة length معامل نوع عام a في توقيع النوع الخاص بها.

length : List a -> Int

المعاملات في الأنواع

عندما يكون نوع ما عامًّا على نوع آخر، نستخدم اسمًا بحروف صغيرة لذلك النوع الآخر، ونسميه معامل نوع. من الأمثلة الشائعة الأنواع المخصصة List وMaybe وResult.

-- Maybe is generic over the type a
type Maybe a
    = Nothing
    | Just a

someString : Maybe String
someString = Just "hello"

someInt : Maybe Int
someInt = Just 42

من الملاحظات المهمة حول أسماء معاملات النوع أنها يمكن أن تتكون من أكثر من حرف واحد. القيد الوحيد هو أنها يجب أن تكون أسماء بحروف صغيرة. لذلك، عندما يكون ذلك مفيدًا، نميل إلى إعطائها أسماء وصفية.

يمكن أن يكون النوع عامًّا على عدة أنواع أخرى، وبالتالي أن يمتلك عدة معاملات نوع. في هذه الحالة، يحصل كل نوع مستقل على اسم مختلف بحروف صغيرة. كون هذه الأنواع مستقلة لا يمنعها من أن تكون النوع نفسه، بل يتيح لها فقط أن تكون مختلفة.

-- Result is generic over the types error and value
type Result error value
    = Ok value
    | Err error

يمكن أن تكون لأسماء أنواع السجلات معاملات نوع أيضًا، وإن كان ذلك أقل شيوعًا.

-- Event is generic over the type a
type alias Event a =
    { at : Time
    , data : a 
    }

معاملات النوع في الدوال

بما أن الأنواع يمكن أن تكون عامة، فكذلك الدوال. يمكن كتابة دوال تتعامل مع أنواع عامة، مثل Maybe.withDefault.

withDefault : a -> Maybe a -> a
withDefault default maybe =
    case maybe of
      Just value -> value
      Nothing -> default

الدوال التي تأخذ دوال أخرى كمعاملات تُسمى الدوال عالية الرتبة، ويمكن أن تكون هذه أيضًا عامة.

map : (a -> b) -> Maybe a -> Maybe b
map function maybe =
  case maybe of
    Just value ->
      Just (function value)

    Nothing ->
      Nothing