खज़ाने का संदूक

जेनेरिक्स

परिचय

जेनेरिक्स भाषा का एक फीचर है जो कोड का दोबारा उपयोग संभव बनाता है। उदाहरण के लिए, किसी ऐरे में किस टाइप की वैल्यू हैं, इससे ऐरे की लंबाई निकालने में फर्क नहीं पड़ना चाहिए। इसीलिए length फंक्शन अपने टाइप सिग्नेचर में एक जेनेरिक टाइप पैरामीटर a इस्तेमाल करता है।

length : List a -> Int

टाइपों में पैरामीटर

जब एक टाइप किसी दूसरे टाइप पर जेनेरिक होता है, तो उस दूसरे टाइप के लिए हम छोटे अक्षरों वाला नाम इस्तेमाल करते हैं और उसे टाइप पैरामीटर कहते हैं। आम उदाहरण List, Maybe और Result कस्टम टाइप हैं।

-- Maybe is generic over the type a
type Maybe a
    = Nothing
    | Just a

someString : Maybe String
someString = Just "hello"

someInt : Maybe Int
someInt = Just 42

टाइप पैरामीटर के नामों के बारे में एक ज़रूरी बात यह है कि वे कई अक्षरों के हो सकते हैं। एकमात्र शर्त यह है कि वे छोटे अक्षरों वाले नाम होने चाहिए। इसलिए जब यह उपयोगी हो, तो हम उन्हें ऐसे नाम देते हैं जो उनका अर्थ बताते हैं।

एक टाइप कई अन्य टाइपों पर जेनेरिक हो सकता है, और इस तरह उसके कई टाइप पैरामीटर हो सकते हैं। ऐसी स्थिति में हर स्वतंत्र टाइप को अलग छोटे अक्षरों वाला नाम मिलता है। स्वतंत्र होना उन्हें एक ही टाइप बनने से नहीं रोकता, यह बस उन्हें अलग होने की सुविधा देता है।

-- Result is generic over the types error and value
type Result error value
    = Ok value
    | Err error

रिकॉर्ड टाइप एलियस में भी टाइप पैरामीटर हो सकते हैं, हालाँकि यह कम आम है।

-- Event is generic over the type a
type alias Event a =
    { at : Time
    , data : a 
    }

फंक्शनों में टाइप पैरामीटर

चूँकि टाइप जेनेरिक हो सकते हैं, इसलिए फंक्शन भी जेनेरिक हो सकते हैं। जेनेरिक टाइपों को संभालने वाले फंक्शन लिखे जा सकते हैं, जैसे Maybe.withDefault।

withDefault : a -> Maybe a -> a
withDefault default maybe =
    case maybe of
      Just value -> value
      Nothing -> default

जो फंक्शन दूसरे फंक्शनों को पैरामीटर के रूप में लेते हैं, उन्हें हायर ऑर्डर फंक्शन कहा जाता है, और ये भी जेनेरिक हो सकते हैं।

map : (a -> b) -> Maybe a -> Maybe b
map function maybe =
  case maybe of
    Just value ->
      Just (function value)

    Nothing ->
      Nothing