蒂斯伯里寻宝

Tuple在很多方面跟Vector（一维array）很像。不过，两者之间也有几处重要的不同。

• 元组用圆括号( )书写，而不是方括号[ ]；不过在含义明确的情况下，圆括号可以省略。
• 元组不要求元素同类型：每个元素的类型都是独立存储的。
• 元组是不可变的。

不可变性让编译器能做更多优化，也让元组的性能优于向量，所以在不需要可变性的情况下应该优先使用元组。

julia> t = (3, 5.2, "xyz")
(3, 5.2, "xyz")

# Non-homogeneous:
julia> dump(t)
Tuple{Int64, Float64, String}
  1: Int64 3
  2: Float64 5.2
  3: String "xyz"

julia> t[2]
5.2

# Immutable:
julia> t[2] = 7.3
ERROR: MethodError: no method matching setindex!(::Tuple{Int64, Float64, String})

还有一个Tuple()构造函数，可以把任何可迭代集合变成元组。很方便的是，它会把字符串视为由字符组成的可迭代集合。

julia> Tuple("Julia")
('J', 'u', 'l', 'i', 'a')

对任何元组，都可以通过下标访问元素，或者对它们进行循环。

任何纯数值元组都能用在sum()这类数学函数中，和数组完全一样。

解包

使用多重赋值可以把元组解包成一个个独立的元素。对于不需要的元素，用下划线_作为占位变量。

julia> tup = (1, "Julia", true)
(1, "Julia", true)

julia> num, name, _ = tup
(1, "Julia", true)

julia> uppercase(name), 2num
("JULIA", 2)

Python 程序员对这种多重赋值语法会非常熟悉。

具名元组

Tuple只包含值。NamedTuple则把每个值和一个名字配对。

这样就能用“点”表示法访问各个字段：

julia> nt = (a = 1, b = 7.3)
(a = 1, b = 7.3)

julia> dump(nt)
@NamedTuple{a::Int64, b::Float64}
  a: Int64 1
  b: Float64 7.3

julia> nt.b
7.3

名字在内部以Symbol的形式存储（一种不可变类型，前面带一个冒号:），所以还有另一种可用的语法：

julia> nt[:b]
7.3

要分别取出名字（也叫“键”）或值都很容易：

julia> nt
(a = 1, b = 7.3)

julia> keys(nt)
(:a, :b)

julia> values(nt)
(1, 7.3)

注意，遍历具名元组时只会产生_值_，_名字_会被忽略。

元组（无论是否具名）都是把结构化数据传入和传出函数的常见方式。在这种场景下，不可变性很有好处，它既能保证数据安全，也能让编译器进行更激进的优化。