Schatzsuche in Tisbury

Ein Tuple ähnelt einem Vector (eindimensionales array) in vielerlei Hinsicht. Es gibt jedoch ein paar wichtige Unterschiede.

• Tupel werden in runden Klammern ( ) geschrieben, nicht in eckigen Klammern [ ]. Die Klammern kannst du allerdings weglassen, wenn die Bedeutung eindeutig ist.
• Tupel müssen nicht homogen sein: Der Typ jedes Elements wird unabhängig gespeichert.
• Tupel sind unveränderlich.

Unveränderlichkeit erlaubt dem Compiler mehr Optimierungen und macht Tupel leistungsfähiger als Vektoren. Deshalb solltest du sie bevorzugen, wenn keine Veränderbarkeit nötig ist.

julia> t = (3, 5.2, "xyz")
(3, 5.2, "xyz")

# Non-homogeneous:
julia> dump(t)
Tuple{Int64, Float64, String}
  1: Int64 3
  2: Float64 5.2
  3: String "xyz"

julia> t[2]
5.2

# Immutable:
julia> t[2] = 7.3
ERROR: MethodError: no method matching setindex!(::Tuple{Int64, Float64, String})

Es gibt außerdem einen Tuple()-Konstruktor, der jede iterierbare Sammlung in ein Tupel umwandelt. Praktischerweise behandelt er einen String als iterierbare Sammlung von Zeichen.

julia> Tuple("Julia")
('J', 'u', 'l', 'i', 'a')

Bei jedem Tupel kannst du auf die Elemente über den Index zugreifen oder sie in einer Schleife durchlaufen.

Jedes rein numerische Tupel kannst du auch in mathematischen Funktionen wie sum() verwenden, genau wie Arrays.

Entpacken

Ein Tupel lässt sich mit Mehrfachzuweisung in einzelne Elemente entpacken. Für Elemente, die du nicht brauchst, verwendest du den Unterstrich _ als Platzhaltervariable.

julia> tup = (1, "Julia", true)
(1, "Julia", true)

julia> num, name, _ = tup
(1, "Julia", true)

julia> uppercase(name), 2num
("JULIA", 2)

Wer Python programmiert, kennt diese Syntax der Mehrfachzuweisung schon gut.

Benannte Tupel

Ein Tuple enthält nur Werte. Ein NamedTuple kombiniert jeden Wert mit einem Namen.

Auf die einzelnen Felder kannst du dann mit der Punkt-Notation zugreifen:

julia> nt = (a = 1, b = 7.3)
(a = 1, b = 7.3)

julia> dump(nt)
@NamedTuple{a::Int64, b::Float64}
  a: Int64 1
  b: Float64 7.3

julia> nt.b
7.3

Der Name wird intern als Symbol gespeichert (ein unveränderlicher Typ mit einem Doppelpunkt : als Präfix), deshalb gibt es noch eine alternative Syntax:

julia> nt[:b]
7.3

Es ist einfach, entweder nur die Namen (auch „Schlüssel“ genannt) oder nur die Werte zu bekommen:

julia> nt
(a = 1, b = 7.3)

julia> keys(nt)
(:a, :b)

julia> values(nt)
(1, 7.3)

Beachte, dass eine Iteration über ein benanntes Tupel nur die Werte liefert und die Namen ignoriert werden.

Tupel (benannt oder nicht) sind ein sehr verbreiteter Weg, strukturierte Daten an Funktionen zu übergeben und von ihnen zurückzubekommen. Unveränderlichkeit ist in diesem Fall von Vorteil: Sie sorgt für Datensicherheit und ermöglicht dem Compiler aggressivere Optimierungen.