Полювання за скарбами в Тісбері

Tuple багато в чому досить схожий на Vector (одновимірний array). Однак є кілька важливих відмінностей.

• Кортежі записують у круглих дужках ( ), а не в квадратних [ ], хоча круглі дужки можна опускати, коли зміст однозначний.
• Кортежі не обовʼязково мають бути однорідними: тип кожного елемента зберігається окремо.
• Кортежі незмінні.

Незмінність дозволяє компілятору краще оптимізувати код і робить кортежі продуктивнішими за вектори, тому їм варто віддавати перевагу там, де змінність не потрібна.

julia> t = (3, 5.2, "xyz")
(3, 5.2, "xyz")

# Non-homogeneous:
julia> dump(t)
Tuple{Int64, Float64, String}
  1: Int64 3
  2: Float64 5.2
  3: String "xyz"

julia> t[2]
5.2

# Immutable:
julia> t[2] = 7.3
ERROR: MethodError: no method matching setindex!(::Tuple{Int64, Float64, String})

Також є конструктор Tuple(), який перетворює будь-яку колекцію, яку можна перебрати, на кортеж. Зручно, що він розглядає рядок тексту (англ. string) як колекцію символів, яку можна перебрати.

julia> Tuple("Julia")
('J', 'u', 'l', 'i', 'a')

Для будь-якого кортежу можна отримати доступ до елементів за індексом або перебрати їх.

Будь-який суто числовий кортеж також можна використати в математичних функціях, як-от sum(), точнісінько як масиви.

Розпакування

Кортеж можна розпакувати на окремі елементи за допомогою множинного присвоєння. Для елементів, які не потрібні, використаймо підкреслення _ як змінну-заглушку.

julia> tup = (1, "Julia", true)
(1, "Julia", true)

julia> num, name, _ = tup
(1, "Julia", true)

julia> uppercase(name), 2num
("JULIA", 2)

Програмістам Python синтаксис множинного присвоєння добре знайомий.

Іменовані кортежі

Tuple містить лише значення. NamedTuple поєднує кожне значення з іменем.

До окремих полів тоді можна отримати доступ через «крапкову» нотацію:

julia> nt = (a = 1, b = 7.3)
(a = 1, b = 7.3)

julia> dump(nt)
@NamedTuple{a::Int64, b::Float64}
  a: Int64 1
  b: Float64 7.3

julia> nt.b
7.3

Імʼя всередині зберігається як Symbol (незмінний тип, перед яким ставиться двокрапка :), тому доступний альтернативний синтаксис:

julia> nt[:b]
7.3

Легко отримати окремо або імена (їх також називають ключами), або значення:

julia> nt
(a = 1, b = 7.3)

julia> keys(nt)
(:a, :b)

julia> values(nt)
(1, 7.3)

Зауважмо, що ітерація за іменованим кортежем дає лише значення, а імена ігноруються.

Кортежі (іменовані чи ні) дуже часто використовують, щоб передавати структуровані дані у функції та з функцій. Незмінність у такому застосуванні корисна: вона забезпечує безпеку даних і дозволяє компілятору агресивніше оптимізувати код.