Tisbury 보물찾기

Tuple은 여러 면에서 Vector(1차원 array)와 아주 비슷해요. 하지만 몇 가지 중요한 차이점이 있어요.

• 튜플은 대괄호 [ ] 대신 소괄호 ( )로 작성해요. 다만 의미가 명확한 경우에는 소괄호를 생략할 수 있어요.
• 튜플은 모든 원소가 같은 타입일 필요가 없어요. 각 원소의 타입이 따로 저장돼요.
• 튜플은 불변이에요.

불변성 덕분에 컴파일러가 더 많은 최적화를 할 수 있고, 튜플은 벡터보다 성능이 좋아요. 그래서 값을 바꿀 필요가 없을 때는 튜플을 쓰는 게 좋아요.

julia> t = (3, 5.2, "xyz")
(3, 5.2, "xyz")

# Non-homogeneous:
julia> dump(t)
Tuple{Int64, Float64, String}
  1: Int64 3
  2: Float64 5.2
  3: String "xyz"

julia> t[2]
5.2

# Immutable:
julia> t[2] = 7.3
ERROR: MethodError: no method matching setindex!(::Tuple{Int64, Float64, String})

Tuple() 생성자도 있어요. 이 생성자는 반복 가능한 모든 컬렉션을 튜플로 바꿔줘요. 유용하게도, 문자열을 문자의 반복 가능한 컬렉션으로 취급해요.

julia> Tuple("Julia")
('J', 'u', 'l', 'i', 'a')

어떤 튜플이든 인덱스로 원소에 접근하거나, 원소를 순회할 수 있어요.

숫자로만 이루어진 튜플은 배열과 똑같이 sum() 같은 수학 함수에 사용할 수 있어요.

구조 분해

여러 개를 한 번에 대입하면 튜플을 각각의 원소로 분해할 수 있어요. 필요하지 않은 원소에는 더미 변수로 밑줄(_)을 사용해요.

julia> tup = (1, "Julia", true)
(1, "Julia", true)

julia> num, name, _ = tup
(1, "Julia", true)

julia> uppercase(name), 2num
("JULIA", 2)

Python 프로그래머라면 이 다중 대입 문법이 아주 익숙할 거예요.

이름 있는 튜플

Tuple은 값만 담아요. NamedTuple은 각 값에 이름을 짝지어 줘요.

그러면 "점" 표기법으로 각 필드에 접근할 수 있어요:

julia> nt = (a = 1, b = 7.3)
(a = 1, b = 7.3)

julia> dump(nt)
@NamedTuple{a::Int64, b::Float64}
  a: Int64 1
  b: Float64 7.3

julia> nt.b
7.3

이름은 내부적으로 Symbol이라는 불변 타입으로 저장돼요. Symbol은 앞에 콜론 :을 붙여요. 그래서 다른 문법도 쓸 수 있어요:

julia> nt[:b]
7.3

값과 이름(또는 "키")을 각각 따로 가져오는 것도 쉬워요:

julia> nt
(a = 1, b = 7.3)

julia> keys(nt)
(:a, :b)

julia> values(nt)
(1, 7.3)

이름 있는 튜플을 순회하면 _값_만 나오고 _이름_은 무시된다는 점에 주의해요.

튜플은 (이름이 있든 없든) 함수와 구조화된 데이터를 주고받는 아주 흔한 방법이에요. 이런 용도에서는 불변성이 좋아요. 데이터 안전성을 보장하고, 컴파일러가 더 적극적으로 최적화할 수 있게 해주니까요.