البحث عن الكنز في Tisbury

يتشابه Tuple مع Vector (أي array أحادي البعد) في نواحٍ كثيرة. لكن هناك بعض الفروق المهمة.

• تُكتب الصفوف بين قوسين هلاليين ( ) بدلًا من قوسين مربعين [ ]، مع أنه يمكن حذف القوسين الهلاليين في الحالات التي لا يكون فيها المعنى ملتبسًا.
• لا يُشترط أن تكون الصفوف متجانسة: إذ يُخزَّن نوع كل عنصر على حدة.
• الصفوف غير قابلة للتغيير.

عدم القابلية للتغيير يسمح للمترجم بإجراء تحسينات أكثر، ويجعل الصفوف أسرع أداءً من المتجهات، لذا يُفضَّل استخدامها حين لا تكون القابلية للتغيير ضرورية.

julia> t = (3, 5.2, "xyz")
(3, 5.2, "xyz")

# Non-homogeneous:
julia> dump(t)
Tuple{Int64, Float64, String}
  1: Int64 3
  2: Float64 5.2
  3: String "xyz"

julia> t[2]
5.2

# Immutable:
julia> t[2] = 7.3
ERROR: MethodError: no method matching setindex!(::Tuple{Int64, Float64, String})

توجد أيضًا البانية Tuple()، التي تحوّل أي مجموعة قابلة للتكرار إلى صف. ومن المفيد أنها تتعامل مع السلسلة النصية بوصفها مجموعة قابلة للتكرار من المحارف.

julia> Tuple("Julia")
('J', 'u', 'l', 'i', 'a')

يمكن الوصول إلى عناصر أي صف عبر الفهرس أو المرور عليها بحلقة.

كما يمكن استخدام أي صف رقمي بحت في الدوال الرياضية مثل sum()، تمامًا مثل المصفوفات.

التفكيك

يمكن تفكيك الصف إلى عناصر منفردة باستخدام الإسناد المتعدد. وللعناصر غير المطلوبة، استخدم الشرطة السفلية _ بوصفها متغيرًا صوريًا.

julia> tup = (1, "Julia", true)
(1, "Julia", true)

julia> num, name, _ = tup
(1, "Julia", true)

julia> uppercase(name), 2num
("JULIA", 2)

سيكون مبرمجو Python على دراية تامة بصيغة الإسناد المتعدد هذه.

الصفوف المسماة

يحتوي Tuple على القيم فقط. أما NamedTuple فيقرن كل قيمة باسم.

ويمكن بعد ذلك الوصول إلى الحقول المفردة باستخدام ترميز "النقطة":

julia> nt = (a = 1, b = 7.3)
(a = 1, b = 7.3)

julia> dump(nt)
@NamedTuple{a::Int64, b::Float64}
  a: Int64 1
  b: Float64 7.3

julia> nt.b
7.3

يُخزَّن الاسم داخليًا بوصفه Symbol (نوع غير قابل للتغيير يُسبق بنقطتين رأسيتين :)، لذا تتوفر صيغة بديلة:

julia> nt[:b]
7.3

من السهل الحصول على الأسماء (وتُسمى أيضًا "المفاتيح") أو على القيم بشكل منفصل:

julia> nt
(a = 1, b = 7.3)

julia> keys(nt)
(:a, :b)

julia> values(nt)
(1, 7.3)

لاحظ أن التكرار على صف مسمّى ينتج القيم فقط، بينما تُهمَل الأسماء.

تُعدّ الصفوف (المسمّاة أو غير المسمّاة) وسيلة شائعة جدًا لنقل البيانات المهيكلة من الدوال وإليها. وعدم القابلية للتغيير مفيد في هذه الحالة، لأنه يوفّر أمان البيانات ويتيح للمترجم إجراء تحسينات أكثر جرأة.