Vectors Concept-এ আমরা বলেছিলাম যে, "অ্যারেগুলো Julia ভাষার মূল ভিত্তি", আর একটি ভেক্টর হলো একমাত্রিক।
এটা মাথায় রেখে আমরা যুক্তিসঙ্গতভাবেই আশা করতে পারি যে, ভাষাটি ভেক্টর নিয়ে কিছু করার জন্য বহুমুখী ও শক্তিশালী অনেক উপায় দেবে, সেটা যা-ই হোক না কেন।
ভেক্টর ইনপুট প্রত্যাশা করে এমন ফাংশন
কিছু খুব সাধারণ ফাংশন একটি ভেক্টর ইনপুট নেয় এবং একটি স্কেলার আউটপুট রিটার্ন করে।
v = [2, 3, 4]
length(v) # => 3
sum(v) # => 9
গাণিতিক ক্রিয়া
ধরুন আপনার কাছে একটি সাংখ্যিক ভেক্টর আছে এবং আপনি প্রতিটি মান থেকে 0.5 বিয়োগ করতে চান।
julia> v = [1.2, 1.5, 1.7]
3-element Vector{Float64}:
1.2
1.5
1.7
julia> v - 0.5
ERROR: MethodError: no method matching -(::Vector{Float64}, ::Float64)
এটা তো ব্যর্থ হলো, তাহলে অন্য একটি ভেক্টর বিয়োগ করলে কী হয়?
julia> v - [0.5, 0.5, 0.5]
3-element Vector{Float64}:
0.7
1.0
1.2
সফল হয় বটে, কিন্তু ভেক্টরগুলো লম্বা হতে থাকলে এটি বেশ ঝামেলার আর প্রচুর মেমোরি খরচ করে।
সৌভাগ্যক্রমে, এই সমস্যাটি খুব সহজেই সমাধান করার জন্য Julia-র কাছে একটি "ম্যাজিক" ডট আছে: আপনার দরকার শুধু v .- 0.5।
পরের অংশে এটির কারণ ব্যাখ্যা করা হয়েছে।
ব্রডকাস্টিং
তাহলে দেখুন, v - 0.5 ব্যর্থ হয় কিন্তু v .- 0.5 সফল হয়, আর ডটটি আসলে কী করছে সেটি আমাদের বুঝতে হবে।
দুটি জিনিস, যেগুলো একসাথে মিলে কাঙ্ক্ষিত ফলাফল দেয়।
1. এলিমেন্টভিত্তিক প্রয়োগ
প্রথমত, যেকোনো ইনফিক্স অপারেটরের আগে একটি ডট বসানোর অর্থ হলো "এই অপারেশনটি প্রতিটি এলিমেন্টে আলাদা আলাদাভাবে প্রয়োগ করা"।
একইভাবে, কোনো ফাংশনের নামের পরে একটি ডট বসালে সেটি "ভেক্টরাইজ" হয়ে যায়, এমনকি ফাংশনটি যদি স্কেলার ইনপুটের জন্য লেখা হয়ে থাকে।
julia> sqrt.([1, 4, 9])
3-element Vector{Float64}:
1.0
2.0
3.0
2. সিঙ্গেলটন সম্প্রসারণ
আগের একটি উদাহরণে দেখেছি যে আমরা সমান দৈর্ঘ্যের ভেক্টর বিয়োগ করতে পারি, তবে দয়া করে বুঝে নিন যে এলিমেন্টভিত্তিক উদ্দেশ্যটি স্পষ্ট করে দেওয়ার কারণে .- অপারেটরটি - অপেক্ষা নিরাপদ।
julia> v .- [0.5, 0.5, 0.5]
3-element Vector{Float64}:
0.7
1.0
1.2
অসমান দৈর্ঘ্যের ভেক্টর হলে কী হবে?
julia> v .- [0.5, 0.5]
ERROR: DimensionMismatch: arrays could not be broadcast to a common size
julia> v .- [0.5,]
3-element Vector{Float64}:
0.7
1.0
1.2
সাধারণভাবে, অসমান দৈর্ঘ্য একটি এরর, তবে তখন নয় যখন একটির দৈর্ঘ্য ১ (প্রযুক্তিগতভাবে একটি "সিঙ্গেলটন" ডাইমেনশন)।
সিঙ্গেলটন, যেমন [0.5,] বা শুধু 0.5, পুনরাবৃত্তির মাধ্যমে স্বয়ংক্রিয়ভাবে প্রয়োজনীয় দৈর্ঘ্যে সম্প্রসারিত হয়।
এই ধারণাটিই broadcasting-এর মূল ভিত্তি।
ইনডেক্সিং
ইনডেক্স নম্বর দিয়ে একটি ভেক্টরের এলিমেন্ট নির্বাচন নিয়ে আগের Concept-গুলোতে আলোচনা করা হয়েছে।
a = collect('A':'Z') # => 26-element Vector{Char}
# index with an integer
a[2] # => 'B'
# index with a range
a[12:2:18] # => ['L', 'N', 'P, 'R']
# index with another vector
a[ [1, 3, 5] ] # => ['A', 'C', 'E']
লজিক্যাল ইনডেক্সিং
কোনো লজিক্যাল এক্সপ্রেশন (প্রযুক্তিগতভাবে একটি "প্রেডিকেট") সন্তুষ্ট করে এমন এলিমেন্টও নির্বাচন করা সম্ভব।
এর জন্য সাধারণত ব্রডকাস্টিং লাগে।
julia> a[a .< 'D']
3-element Vector{Char}:
'A': ASCII/Unicode U+0041 (category Lu: Letter, uppercase)
'B': ASCII/Unicode U+0042 (category Lu: Letter, uppercase)
'C': ASCII/Unicode U+0043 (category Lu: Letter, uppercase)
আরও জটিল এক্সপ্রেশনের ক্ষেত্রে ডটগুলো বেড়ে যেতে থাকে (তবে এগুলো ছোট আর টাইপ করা সহজ)।
julia> a[a .< 'D' .|| a .> 'W']
6-element Vector{Char}:
'A': ASCII/Unicode U+0041 (category Lu: Letter, uppercase)
'B': ASCII/Unicode U+0042 (category Lu: Letter, uppercase)
'C': ASCII/Unicode U+0043 (category Lu: Letter, uppercase)
'X': ASCII/Unicode U+0058 (category Lu: Letter, uppercase)
'Y': ASCII/Unicode U+0059 (category Lu: Letter, uppercase)
'Z': ASCII/Unicode U+005A (category Lu: Letter, uppercase)
মনে রাখবেন, "ভেক্টর" আসলে যেকোনো উপযুক্ত ক্রমবদ্ধ ইটারেবল হতে পারে, যেমন একটি রেঞ্জ:
julia> n = 3:10
3:10
julia> n[isodd.(n)]
4-element Vector{Int64}:
3
5
7
9
লার্নিং অনুশীলনী
