মুদ্রা বিনিময়

জুলিয়া একটি সাধারণ উদ্দেশ্যে ব্যবহারযোগ্য ভাষা, যা বেশিরভাগ প্রোগ্রামিং কাজে ব্যবহার করা যায়। তবে বাস্তবে এর প্রধান ব্যবহারগুলো মূলত ইঞ্জিনিয়ারিং ও বিজ্ঞানে। দ্রুত, বহুমুখী ও অত্যাধুনিক সংখ্যাগত গণনা এই ভাষার নকশার কেন্দ্রে আছে।

ইন্টিজার

ইন্টিজার হলো একটি "গোল" সংখ্যা, যার কোনো দশমিক বিন্দু থাকে না।

বেসিকস কনসেপ্টে আমরা দেখেছি যে, টাইপ উল্লেখ না করেই একটি ভ্যারিয়েবলে ইন্টিজার মান অ্যাসাইন করা যায়।

পড়ার সুবিধার জন্য আন্ডারস্কোরকে ডিজিট আলাদা করার চিহ্ন হিসেবে ব্যবহার করা যায়। কম্পাইলার এগুলো উপেক্ষা করে।

julia> x = 3
3

julia> typeof(x)
Int64

julia> large_number = 1_234_567_890
1234567890

ফ্লোটিং-পয়েন্ট

এটা আর আশ্চর্যের কিছু নয় যে ফ্লোটিং-পয়েন্ট সংখ্যায় একটি দশমিক বিন্দু থাকে, আর বিন্দুর পরে একটি ভগ্নাংশ থাকে।

julia> f = 3.45
3.45

julia> typeof(f)
Float64

অবশ্যই, বৈজ্ঞানিক নোটেশনও সমর্থিত।

julia> avogadro = 6.02e23
6.02e23

সর্বোচ্চ ও সর্বনিম্ন মান দেখে আপনি হয়তো অবাক হতে পারেন:

julia> typemax(Float64)
Inf

julia> typemin(Float64)
-Inf

ইনফিনিটি একটি বৈধ মান!

গাণিতিক অপারেটর

বেসিকস কনসেপ্টে আলোচনা করা হয়েছে, গাণিতিক অপারেটরগুলো বেশিরভাগ ক্ষেত্রেই ছোটদের শেখানো সাধারণ পাটিগণিতের মতোই কাজ করে। মনে রাখবেন, সূচকীকরণে ^ ব্যবহার হয়, ** নয় (দুটোই অন্য ভাষায় প্রচলিত)।

2 + 3  # 5 (addition)
2 - 3  # -1 (subtraction)
2 * 3  # 6 (multiplication)
8 / 2  # 4.0 (division)
8 % 3  # 2 (remainder)
2 ^ 3  # 8 (exponentiation)

তবে জুলিয়ার কিছু নিজস্ব বিষয় আলোচনার যোগ্য।

গুণ

julia> x = 4.2
4.2

julia> 2 * x
8.4

julia> 2x
8.4

julia> 2.4x
10.08

এটা হয়তো অবাক করার মতো।

অন্য বেশিরভাগ কম্পিউটার ভাষার মতোই, *-কে ইনফিক্স অপারেটর হিসেবে ব্যবহার করা সবসময়ই সম্ভব।

কিন্তু যাঁরা জুলিয়া তৈরি করেছেন, তাঁরা মনে করেন কোড যতটা সম্ভব গাণিতিক সমীকরণের মতো হওয়া উচিত।

যেহেতু ভ্যারিয়েবলের নাম অবশ্যই একটি অক্ষর দিয়ে শুরু হতে হয়, তাই নামের আগে একটি সংখ্যা (ইন্টিজার বা ফ্লোটিং-পয়েন্ট) বসালে সেটি অন্তর্নিহিত গুণ হিসেবে ধরে নেওয়া হয়।

উদাহরণস্বরূপ, একটি গোলকের পৃষ্ঠতলের ক্ষেত্রফল বের করতে চাইলে 4 * pi * r * r-এর বদলে আমরা এভাবে লিখতে পারি:

julia> surface(r) = 4π * r^2
surface (generic function with 1 method)

julia> surface(3)
113.09733552923255

যদিও π একটি বিল্ট-ইন ধ্রুবক, এটি আসলে একটি (গ্রিক) অক্ষরও বটে। তাই π-কে r থেকে আলাদা করতে পার্সারের এখনও একটি স্পষ্ট * দরকার হয়।

ভাগ

ইনফিক্স অপারেটর হিসেবে / ব্যবহার করলে সবসময়ই ফ্লোটিং-পয়েন্ট ফলাফল পাওয়া যায়, এমনকি ইন্টিজার ইনপুটের ক্ষেত্রেও।

ইন্টিজার ভাগের জন্য আরও কিছু উপায় আছে।

julia> 10 / 3  # floating-point division
3.3333333333333335

julia> div(10, 3)  # integer division
3

julia> 10 ÷ 3  # synonym for div()
3

julia> 10 // 3  # rational number (fraction)
10//3

div() ফাংশনটি ইন্টিজার ভাগের জন্য, যেখানে ফলাফল শূন্যের দিকে ছেঁটে দেওয়া হয়: ধনাত্মক সংখ্যার ক্ষেত্রে নিচের দিকে, ঋণাত্মক সংখ্যার ক্ষেত্রে উপরের দিকে।

সমার্থক হিসেবে আমরা ইনফিক্স অপারেটর ÷ ব্যবহার করতে পারি, যা আবারও এটিকে গাণিতিক দেখানোর চেষ্টা। আপনি যদি জুলিয়া-সচেতন এডিটর ব্যবহার করেন, তাহলে \div টাইপ করে <Tab> চাপুন।

// অপারেটরটি এই কনসেপ্টের পরিধির বাইরে। আপাতত আমরা শুধু বলতে পারি, //-এর ফলাফল একটি "রেশনাল" সংখ্যা, যেটিকে বেশিরভাগ মানুষ ভগ্নাংশ বলে।

সংখ্যার টাইপ রূপান্তর

এটি প্রায়ই স্বয়ংক্রিয়ভাবে ঘটে থাকে:

julia> x = 2 + 3.5
5.5

julia> typeof(x)
Float64

আমরা একটি Int64-এর সাথে একটি Float64 যোগ করেছি, আর ফলাফল পেয়েছি Float64।

আসলে যোগ করার আগেই ইন্টিজারটি নিঃশব্দে Float64-এ রূপান্তর করা হয়েছিল।

ফ্লোট থেকে ইন্টিজার রূপান্তর অনিবার্যভাবে আরও জটিল। দশমিক বিন্দুর পরের অংশ নিয়ে আপনি কী করতে চান?

• round() ফাংশনটি নিকটতম পূর্ণসংখ্যায় রূপান্তর করে, আর 4.5-এর মতো সমান দূরত্বের ক্ষেত্রে নিকটতম জোড় পূর্ণসংখ্যায় রাউন্ড করে।
• floor() নিচের দিকে রাউন্ড করে, ceil() উপরের দিকে, আর trunc() শূন্যের দিকে।
• সরাসরি কাস্ট করার চেষ্টা করলে, যেমন Int32() দিয়ে, একটি InexactError এরর হবে।

তবে ডিফল্টভাবে এই ফাংশনগুলো আপনার কাঙ্ক্ষিত ইন্টিজার টাইপ রিটার্ন করে না। আপনি চাইলে আউটপুটের টাইপ নির্দিষ্ট করে দিতে পারেন।

julia> round(4.5)
4.0

julia> ceil(Int, 4.3)
5

digits কিওয়ার্ড ব্যবহার করে দশমিক বিন্দুর পরে নির্দিষ্ট সংখ্যক ডিজিটে রাউন্ড করাও সম্ভব।

julia> round(π, digits=10)
3.1415926536

শূন্য দিয়ে ভাগ

নিশ্চয়ই এতে শুধু একটি এরর হয়? আসলে ব্যাপারটা তত সহজ নয়।

আপনি যেমন আশা করতে পারেন, ÷ বা // দিয়ে ইন্টিজার ভাগ করলে এরর হয়।

/ দিয়ে ফ্লোটিং-পয়েন্ট ভাগ করলে সাধারণ কম্পিউটার সায়েন্সের বদলে ইঞ্জিনিয়ারিংয়ের মতো একটা দৃষ্টিভঙ্গি নেওয়া হয়:

julia> 2 / 0
Inf

julia> 0 / 0
NaN

আগের একটি অংশে আলোচনা করা হয়েছে, জুলিয়ায় ইনফিনিটি একটি বৈধ ফ্লোটিং-পয়েন্ট সংখ্যা, যা Inf দিয়ে প্রকাশ করা হয়।

লবও যদি শূন্য হয়, তাহলে ফলাফলটি গাণিতিকভাবে অসংজ্ঞায়িত। তখন জুলিয়া এটিকে "সংখ্যা নয়" হিসেবে ধরে, যা NaN দিয়ে প্রকাশ করা হয়।