跟风者

记录

记录是一种数据结构，把相关的信息用标签组织在一起。它们类似于 JavaScript 或 Java 中的对象，也类似于 C 或 Rust 中的 struct，但有一些关键区别。

创建记录

记录用花括号创建，其中的元素用逗号分隔。

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

记录的类型也用类似的语法定义，只不过等号=换成了冒号:。

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

重复写这些类型定义很麻烦，所以用类型别名来共享定义是一种常见的做法。

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

类型别名还会自动为记录提供一个构造函数。这一点有时会让人意外，因为 Elm 中的函数必须以小写字符开头，但类型构造器是一个例外。

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

访问记录的字段

访问记录实例中某个字段的值的主要方式是使用点号表示法，比如firefly.creator。Elm 编译器还支持以点.开头的特殊访问器函数，比如.creator，它可以作用于任何含有同名字段的记录。这是“函数必须以小写字符开头”这条规则的第二个例外。事实上，用户自定义的函数必须以小写字符开头，而我们刚刚发现的这两个例子是由编译器生成的，不是程序员写的。

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

记录还可以在绑定中通过记录模式匹配进行解构。解构适用于任何含有相应名称字段的记录。

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

更新记录

和 Elm 中的一切一样，记录是不可变的，所以一旦定义了记录，它的字段值就永远不会改变。有一种特殊语法可以创建现有记录的副本，同时修改一个或多个字段。这种语法用管道符号|来区分原始记录和将要修改的字段，比如{ oldRecord | field1 = newValue }。

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

比较记录

Elm 使用[结构相等][equality]，也就是说，同一个记录的两个实例只要值完全相同，就相等。

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

可扩展记录

Elm 还支持结构类型，也就是说，如果一个函数需要一个带有 x 和 y 字段的记录，那么任何含有这些字段的记录都可以用，比如二维点、三维点、宇宙飞船等等。这类记录类型的定义中带有一个管道|，比如{ a | x : Float, y : Float }，在 Elm 术语中叫做“可扩展记录”。要小心区分类型定义中的管道|（那是可扩展记录的定义，比如{ a | x : Int }）和实际记录实例中的管道|（那表示我们正在修改该记录的一些字段）。

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }