Le suiveur

Enregistrements

Les enregistrements sont des structures de données qui regroupent des informations liées entre elles sous des étiquettes. Ils sont similaires aux objets en JavaScript ou en Java, ou aux structs en C ou en Rust, mais avec quelques différences essentielles.

Crée des enregistrements

Les enregistrements se créent avec des accolades et leurs éléments sont séparés par des virgules.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Le type d'un enregistrement se définit aussi avec une syntaxe similaire, sauf que les signes égal = sont remplacés par des deux-points :.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Répéter ces définitions de type est fastidieux, c'est pourquoi utiliser un alias de type pour partager la définition est une pratique courante.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

L'alias de type fournit aussi automatiquement une fonction de construction pour l'enregistrement. Cela surprend parfois, car en Elm les fonctions doivent commencer par une minuscule, mais les constructeurs de type sont une exception.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

Accède aux champs d'un enregistrement

La principale façon d'accéder à la valeur d'un champ d'une instance d'enregistrement est d'utiliser la notation pointée, comme firefly.creator. Le compilateur Elm prend aussi en charge des fonctions d'accès spéciales qui commencent par un point ., comme .creator, et qui fonctionnent sur n'importe quel enregistrement ayant un champ de ce nom. C'est la deuxième exception à la règle selon laquelle les fonctions doivent commencer par une minuscule. En fait, les fonctions définies par l'utilisateur doivent commencer par une minuscule, mais les deux exemples que l'on vient de découvrir sont générés par le compilateur, pas par le programmeur.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

Les enregistrements peuvent aussi être déstructurés dans des liaisons, grâce au filtrage par motif sur les enregistrements. La déstructuration fonctionne avec n'importe quel enregistrement qui possède des champs portant les noms concernés.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

Mets à jour des enregistrements

Les enregistrements sont immuables, comme tout en Elm, donc une fois qu'un enregistrement est défini, les valeurs de ses champs ne peuvent plus jamais changer. Il existe une syntaxe spéciale pour créer une copie d'un enregistrement existant tout en modifiant un ou plusieurs de ses champs. Cette syntaxe utilise le symbole barre verticale | pour distinguer l'enregistrement d'origine et les champs qui vont changer, comme { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

Compare des enregistrements

Elm utilise l'[égalité structurelle][equality], ce qui signifie que deux instances du même enregistrement avec des valeurs identiques sont égales.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

Enregistrements extensibles

Elm prend aussi en charge le typage structurel, ce qui signifie que si une fonction a besoin d'un enregistrement avec un champ x et un champ y, elle fonctionnera avec n'importe quel enregistrement possédant ces champs, comme des points 2D, des points 3D, des vaisseaux spatiaux, etc. Ces types d'enregistrement comportent une barre verticale | dans leur définition, comme { a | x : Float, y : Float }, et sont appelés « enregistrements extensibles » dans la terminologie d'Elm. Attention à la différence entre une barre verticale | dans une définition de type, qui est une définition d'enregistrement extensible ({ a | x : Int }), et une barre verticale | dans une instance d'enregistrement réelle, qui signifie que l'on met à jour certains champs de cet enregistrement.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }