Subido al carro

Registros

Los registros son estructuras de datos que agrupan información relacionada con etiquetas. Son similares a los objetos en JavaScript o Java, o a los structs en C o Rust, pero con algunas diferencias clave.

Creación de registros

Los registros se crean con llaves y sus elementos se separan por comas.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

El tipo de un registro también se define con una sintaxis similar, excepto que los signos igual = se sustituyen por dos puntos :.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Repetir estas definiciones de tipo es engorroso, así que usar un alias de tipo para compartir la definición es una práctica común.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

El alias de tipo también proporciona automáticamente una función constructora para el registro. Esto a veces sorprende, ya que las funciones en Elm deben empezar por un carácter en minúscula, pero los constructores de tipo son una excepción.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

Acceso a los campos de un registro

La forma principal de acceder al valor de un campo de una instancia de registro es usar la notación de punto, como firefly.creator. El compilador de Elm también admite funciones de acceso especiales que empiezan por un punto ., como .creator, que funcionan con cualquier registro que tenga un campo con ese nombre. Esa es la segunda excepción a la regla de que las funciones deben empezar por un carácter en minúscula. De hecho, las funciones definidas por el usuario deben empezar por un carácter en minúscula, pero los dos ejemplos que acabamos de descubrir los genera el compilador, no el programador.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

Los registros también se pueden desestructurar en vinculaciones usando la coincidencia de patrones de registros. La desestructuración funciona con cualquier registro que tenga campos con los nombres correspondientes.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

Actualización de registros

Los registros son inmutables, como todo en Elm, así que una vez que se define un registro, los valores de sus campos nunca pueden cambiar. Existe una sintaxis especial para crear una copia de un registro existente, pero cambiando uno o varios campos. Esta sintaxis usa el símbolo de barra vertical | para distinguir el registro original y los campos que cambiarán, como { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

Comparación de registros

Elm usa la igualdad estructural, lo que significa que dos instancias del mismo registro con valores idénticos son iguales.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

Registros extensibles

Elm también admite el tipado estructural, lo que significa que si una función requiere un registro con un campo x y otro y, funcionará con cualquier registro que tenga esos campos, como puntos 2D, puntos 3D, naves espaciales, etc. Esos tipos de registro tienen una barra vertical | en su definición, como { a | x : Float, y : Float }, y se denominan «registros extensibles» en la terminología de Elm. Ten cuidado con la diferencia entre una barra vertical | en una definición de tipo, que es una definición de registro extensible ({ a | x : Int }), y una barra vertical | en una instancia de registro real, que significa que estamos actualizando algunos campos de ese registro.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }