Mitläufer

Records

Records sind Datenstrukturen, die zusammengehörige Informationen unter Bezeichnungen bündeln. Sie ähneln Objekten in JavaScript oder Java oder Structs in C oder Rust, weisen aber einige wichtige Unterschiede auf.

Records erstellen

Records werden mit geschweiften Klammern erstellt und ihre Elemente werden durch Kommas getrennt.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Der Typ eines Records wird ebenfalls mit einer ähnlichen Syntax definiert, nur dass Gleichheitszeichen = durch Doppelpunkte : ersetzt werden.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Diese Typdefinitionen immer zu wiederholen ist mühsam, deshalb ist es ein gängiges Vorgehen, ein Typ-Alias zu verwenden, um die Definition zu teilen.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Das Typ-Alias liefert außerdem automatisch eine Konstruktorfunktion für den Record. Das ist manchmal überraschend, denn Funktionen in Elm müssen mit einem Kleinbuchstaben beginnen, aber Typkonstruktoren sind eine Ausnahme.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

Auf Record-Felder zugreifen

Der wichtigste Weg, auf einen Feldwert einer Record-Instanz zuzugreifen, ist die Punktnotation wie firefly.creator. Der Elm-Compiler unterstützt außerdem spezielle Zugriffsfunktionen, die mit einem Punkt . beginnen, wie .creator. Sie funktionieren mit jedem Record, der ein Feld mit diesem Namen hat. Das ist die zweite Ausnahme von der Regel, dass Funktionen mit einem Kleinbuchstaben beginnen müssen. Tatsächlich müssen selbst definierte Funktionen mit einem Kleinbuchstaben beginnen, aber die beiden Beispiele, die wir gerade entdeckt haben, erzeugt der Compiler, nicht der Programmierer.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

Records können in Bindungen auch destrukturiert werden, und zwar mit dem Record-Musterabgleich. Das Destrukturieren funktioniert mit jedem Record, der Felder mit den passenden Namen hat.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

Records aktualisieren

Records sind unveränderlich, wie alles in Elm. Sobald ein Record definiert ist, können sich seine Feldwerte also nie mehr ändern. Es gibt aber eine spezielle Syntax, um eine Kopie eines bestehenden Records zu erstellen und dabei ein oder mehrere Felder zu ändern. Diese Syntax verwendet das Pipe-Symbol |, um den ursprünglichen Record von den Feldern zu unterscheiden, die sich ändern, zum Beispiel { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

Records vergleichen

Elm verwendet [strukturelle Gleichheit][equality]. Das bedeutet, dass zwei Instanzen desselben Records mit identischen Werten gleich sind.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

Erweiterbare Records

Elm unterstützt außerdem strukturelle Typisierung. Das bedeutet: Wenn eine Funktion einen Record mit einem x- und einem y-Feld benötigt, funktioniert sie mit jedem Record, der diese Felder hat, zum Beispiel mit 2D-Punkten, 3D-Punkten, Raumschiffen und so weiter. Solche Record-Typen haben ein Pipe | in ihrer Definition, zum Beispiel { a | x : Float, y : Float }, und heißen in der Elm-Terminologie „erweiterbare Records“. Achte auf den Unterschied zwischen einem Pipe | in einer Typdefinition, das heißt einer erweiterbaren Record-Definition ({ a | x : Int }), und einem Pipe | in einer tatsächlichen Record-Instanz, das bedeutet, dass wir einige Felder dieses Records aktualisieren.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }