Seguidor da moda

Registos

Os registos são estruturas de dados que agrupam informação relacionada com etiquetas. São semelhantes a objetos em JavaScript ou Java, ou a structs em C ou Rust, mas com algumas diferenças importantes.

Criar registos

Os registos são criados com chavetas e os seus elementos são separados por vírgulas.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

O tipo de um registo também se define com uma sintaxe semelhante, exceto que os sinais de igual = são substituídos por dois pontos :.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Repetir estas definições de tipo é maçador, por isso usar um type alias para partilhar a definição é uma prática comum.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

O type alias também fornece automaticamente uma função construtora para o registo. Isto por vezes surpreende, porque as funções em Elm têm de começar por um caráter minúsculo, mas os construtores de tipo são uma exceção.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

Aceder aos campos de um registo

A forma principal de aceder ao valor de um campo de uma instância de um registo é usar a notação de ponto, como firefly.creator. O compilador de Elm também suporta funções de acesso especiais que começam por um ponto ., como .creator, que funcionam em qualquer registo que tenha um campo com esse nome. É a segunda exceção à regra de que as funções têm de começar por um caráter minúsculo. Na verdade, as funções definidas pelo programador têm de começar por um caráter minúsculo, mas os dois exemplos que acabámos de ver são gerados pelo compilador, não pelo programador.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

Os registos também podem ser desestruturados em ligações, usando a correspondência de padrões de registos. A desestruturação funciona com qualquer registo que tenha campos com os nomes relevantes.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

Atualizar registos

Os registos são imutáveis, tal como tudo em Elm, por isso, depois de um registo estar definido, os valores dos seus campos nunca podem mudar. Existe uma sintaxe especial para criar uma cópia de um registo existente, alterando um ou mais campos. Esta sintaxe usa o símbolo de barra vertical | para distinguir o registo original dos campos que vão mudar, como em { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

Comparar registos

Elm usa [igualdade estrutural][equality], o que significa que duas instâncias do mesmo registo com valores idênticos são iguais.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

Registos extensíveis

Elm também suporta tipagem estrutural, ou seja, se uma função exige um registo com um campo x e um campo y, vai funcionar com qualquer registo que tenha esses campos, como pontos 2D, pontos 3D, naves espaciais, etc. Esses tipos de registo têm uma barra vertical | na sua definição, como { a | x : Float, y : Float }, e são chamados "registos extensíveis" na terminologia de Elm. Tem atenção à diferença entre uma barra vertical | numa definição de tipo, que é uma definição de registo extensível ({ a | x : Int }), e uma barra vertical | numa instância de registo real, que significa que estamos a atualizar alguns campos desse registo.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }