Oportunista

Registros

Registros são estruturas de dados que agrupam informações relacionadas com rótulos. Eles são semelhantes a objetos em JavaScript ou Java, ou a structs em C ou Rust, mas com algumas diferenças importantes.

Criando registros

Os registros são criados com chaves e seus elementos são separados por vírgulas.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

O tipo de um registro também é definido com uma sintaxe semelhante, exceto que os sinais de igual = são substituídos por dois-pontos :.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Repetir essas definições de tipo é trabalhoso, então usar um type alias para compartilhar a definição é uma prática comum.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

O type alias também fornece automaticamente uma função construtora para o registro. Isso às vezes surpreende, já que funções em Elm devem começar com uma letra minúscula, mas construtores de tipo são uma exceção.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

Acessando campos de registros

A principal forma de acessar o valor de um campo de uma instância de registro é usar a notação de ponto, como firefly.creator. O compilador Elm também oferece suporte a funções de acesso especiais que começam com um ponto ., como .creator, que funcionam em qualquer registro com um campo desse nome. Essa é a segunda exceção à regra de que funções devem começar com uma letra minúscula. Na verdade, funções definidas pelo usuário devem começar com uma letra minúscula, mas os dois exemplos que acabamos de ver são gerados pelo compilador, não pelo programador.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

Registros também podem ser desestruturados em associações usando a correspondência de padrões de registro. A desestruturação funciona com qualquer registro que tenha campos com os nomes relevantes.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

Atualizando registros

Registros são imutáveis, como tudo em Elm, então, depois que um registro é definido, os valores de seus campos nunca podem mudar. Há uma sintaxe especial para criar uma cópia de um registro existente, mas alterando um ou mais campos. Essa sintaxe usa o símbolo de barra vertical | para distinguir o registro original e os campos que serão alterados, como { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

Comparando registros

Elm usa [igualdade estrutural][equality], o que significa que duas instâncias do mesmo registro com valores idênticos são iguais.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

Registros extensíveis

Elm também oferece suporte à tipagem estrutural, o que significa que, se uma função exige um registro com campos x e y, ela funcionará com qualquer registro que tenha esses campos, como pontos 2D, pontos 3D, naves espaciais, etc. Esses tipos de registro têm uma barra vertical | em sua definição, como { a | x : Float, y : Float }, e são chamados de "registros extensíveis" na terminologia de Elm. Cuidado com a diferença entre uma barra vertical | em uma definição de tipo, que é uma definição de registro extensível ({ a | x : Int }), e uma barra vertical | em uma instância de registro real, que significa que estamos atualizando alguns campos desse registro.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }