Попутник

Записи

Записи - це структури даних, які обʼєднують повʼязану інформацію під мітками. Вони схожі на обʼєкти в JavaScript чи Java або на структури в C чи Rust, але мають кілька важливих відмінностей.

Створення записів

Записи створюються за допомогою фігурних дужок, а їхні елементи розділяються комами.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Тип запису визначається схожим синтаксисом, лише замість знаків рівності = використовуються двокрапки :.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Повторювати ці визначення типів незручно, тому псевдонім типу для спільного визначення - поширений прийом.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

Псевдонім типу також автоматично надає функцію-конструктор для запису. Іноді це дивує, адже функції в Elm мають починатися з малої літери, але конструктори типів - один із винятків.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

Доступ до полів запису

Основний спосіб отримати доступ до значення поля примірника запису - використати точкову нотацію, наприклад firefly.creator. Компілятор Elm також підтримує спеціальні функції доступу, що починаються з крапки ., наприклад .creator, які працюють із будь-яким записом, що має поле з такою назвою. Це другий виняток із правила, що функції мають починатися з малої літери. Насправді функції, визначені користувачем, мають починатися з малої літери, але два щойно розглянуті приклади створює компілятор, а не програміст.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

Записи також можна деструктуризувати у привʼязках за допомогою зіставлення зі зразком для записів. Деструктуризація працює з будь-яким записом, що має поля з відповідними назвами.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

Оновлення записів

Записи незмінні, як і все в Elm, тож щойно запис визначено, значення його полів уже не можуть змінитися. Існує спеціальний синтаксис, щоб створити копію наявного запису, але зі зміненими одним або кількома полями. Цей синтаксис використовує символ вертикальної риски |, щоб відрізнити початковий запис від полів, які зміняться, наприклад { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

Порівняння записів

Elm використовує [структурну рівність][equality], тобто два примірники одного запису з однаковими значеннями вважаються рівними.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

Розширювані записи

Elm також підтримує структурну типізацію: якщо функції потрібен запис із полями x та y, вона працюватиме з будь-яким записом, що має ці поля, наприклад із двовимірними точками, тривимірними точками, космічними кораблями тощо. Такі типи записів мають у своєму визначенні вертикальну риску |, наприклад { a | x : Float, y : Float }, і в термінології Elm називаються «розширюваними записами». Звернімо увагу на різницю між вертикальною рискою | у визначенні типу, що є визначенням розширюваного запису ({ a | x : Int }), та вертикальною рискою | у самому примірнику запису, яка означає, що ми оновлюємо деякі поля цього запису.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }