همراه موج

رکورد

«رکورد» یک ساختار داده است که اطلاعات مرتبط را با برچسب در کنار هم گروه‌بندی می‌کند. این‌ها شبیه به شیءها در JavaScript یا Java یا ساختارها در C یا Rust هستند، اما چند تفاوت کلیدی دارند.

ساختن رکوردها

رکوردها با آکولاد ساخته می‌شوند و عناصرشان با کاما از هم جدا می‌شوند.

firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

نوع یک رکورد هم به شکلی مشابه تعریف می‌شود، با این تفاوت که علامت‌های مساوی = با علامت‌های دونقطه : جایگزین می‌شوند.

firefly : { name : String, creator : String, episodes : Int }
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

تکرار این تعریف‌های نوع دست‌وپاگیر است، بنابراین استفاده از یک نام مستعار نوع برای به اشتراک گذاشتن تعریف، روشی رایج است.

type alias TvSeries =
    { name : String
    , creator : String
    , episodes : Int
    }

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

نام مستعار نوع همچنین به‌طور خودکار یک تابع سازنده برای رکورد فراهم می‌کند. این موضوع گاهی غافلگیرکننده است، چون توابع در Elm باید با یک حرف کوچک شروع شوند، اما سازنده‌های نوع یک استثنا هستند.

firefly : TvSeries
firefly = TvSeries "Firefly" "Joss Whedon" 14

دسترسی به فیلدهای رکورد

راه اصلی دسترسی به مقدار یک فیلد از یک نمونه‌ی رکورد استفاده از نگارش نقطه‌ای است، مانند firefly.creator. کامپایلر Elm هم از توابع دسترسی ویژه که با یک نقطه . شروع می‌شوند، مانند .creator، پشتیبانی می‌کند؛ این توابع روی هر رکوردی با فیلدی به آن اسم کار می‌کنند. این دومین استثنا بر این قاعده است که توابع باید با یک حرف کوچک شروع شوند. در واقع، توابع تعریف‌شده توسط کاربر باید با یک حرف کوچک شروع شوند، اما دو نمونه‌ای که تازه کشف کردیم توسط کامپایلر تولید می‌شوند، نه برنامه‌نویس.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

firefly.name
    --> "Firefly"

.creator firefly
    --> "Joss Whedon"

رکوردها را همچنین می‌توان در اتصال‌ها با استفاده از تطبیق الگوی رکورد تجزیه کرد. تجزیه با هر رکوردی که فیلدهایی با اسم‌های مربوطه داشته باشد کار می‌کند.

episodesCount : TvSeries -> Int
episodesCount { episodes } =
    episodes

complicatedCopy : TvSeries -> TvSeries
complicatedCopy show =
    let
        { name, creator } = show
    in
    { name = name
    , creator = creator
    , episodes = episodesCount show
    }

به‌روزرسانی رکوردها

رکوردها مانند هر چیز دیگری در Elm تغییرناپذیر هستند، بنابراین وقتی رکوردی تعریف شد، مقادیر فیلدهایش هرگز نمی‌توانند تغییر کنند. یک نحوه‌ی نگارش ویژه برای ساختن یک کپی از رکوردی موجود و تغییر یک یا چند فیلد آن وجود دارد. این نگارش از نماد خط عمودی | برای تفکیک رکورد اصلی از فیلدهایی که تغییر خواهند کرد استفاده می‌کند، مانند { oldRecord | field1 = newValue }.

firefly : TvSeries
firefly =
    { name = "Firefly"
    , creator = "Joss Whedon"
    , episodes = 14
    }

updatedFirefly : TvSeries
updatedFirefly =
    { firefly | creator = "J Whedon", episodes = 15 }

مقایسه‌ی رکوردها

Elm از [برابری ساختاری][equality] استفاده می‌کند، یعنی دو نمونه از یک رکورد با مقادیر یکسان برابر هستند.

firefly1 = TvSeries "Firefly" "Joss Whedon" 14
firefly2 = TvSeries "Firefly" "Joss Whedon" 14

firefly1 == firefly2
    --> True

رکوردهای قابل‌گسترش

Elm همچنین از نوع‌دهی ساختاری پشتیبانی می‌کند، یعنی اگر تابعی به رکوردی با فیلدهای x و y نیاز داشته باشد، با هر رکوردی که آن فیلدها را داشته باشد کار می‌کند، مانند نقاط دوبعدی، نقاط سه‌بعدی، سفینه‌های فضایی و غیره. آن نوع‌های رکورد در تعریفشان یک خط عمودی | دارند، مانند { a | x : Float, y : Float }، و در اصطلاح Elm «رکوردهای قابل‌گسترش» نامیده می‌شوند. مراقب تفاوت میان یک خط عمودی | در تعریف نوع باشید، که تعریف یک رکورد قابل‌گسترش است ({ a | x : Int })، و یک خط عمودی | در یک نمونه‌ی واقعی رکورد، که یعنی داریم چند فیلد از آن رکورد را به‌روزرسانی می‌کنیم.

point2d = { x = 1, y = 2 }
point3d = { x = 3, y = 4, z = 7 }

.x point2d --> 1
.x point3d --> 3

length : { a | x : Float, y : Float } -> Float
length vector =
    sqrt (vector.x * vector.x + vector.y * vector.y)

length point2d --> 2.236068
length point3d --> 5

translateX : { a | x : Float } -> { a | x : Float }
translateX vector =
    { vector | x = vector.x + 1 }

translateX point2d --> { x = 2, y = 2 }
translateX point3d --> { x = 4, y = 4, z = 7 }