Blorkemon 卡牌

比较

相等性

Elm 中可以用相等运算符 (==)检查两个值是否“相同”。 不等运算符是 (/=)（不是许多语言里的 !=）。 相等运算符可用于字面量、元组、记录和自定义类型。

1 == 2
    --> False

1 /= 2
    --> True

(1, 2) == (2, 1)
    --> False

type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]

type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings =  (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}

a == b
    --> True

注意，绝对不要比较函数，否则程序会在运行时崩溃。

比较

比较运算符 (<)、(<=)、(>)、(>=) 以及函数 min、max、compare 都作用于 comparable类型。 comparable是一种特殊类型，它把所有可比较的内置类型归为一组：数字、字符、字符串、由可比较的值构成的列表，以及由可比较的值构成的元组。

1 < 1 + 1
    --> True

'x' < 'X'
    --> False

"abc" < "abz"
    --> True

"abc" < "abcd"
    --> True

"abc" < "b"
    --> True

min [1 , 2, 9000] [10]
    --> [1 , 2, 9000]

min (1, "hello") (3, "bye")
    --> (1, "hello")

记录或自定义类型等其他类型的值无法直接比较。

有些内置类型要求其内容必须是comparable，例如Set或Dict的键，因为它们的数据结构依赖于内部的排序。

由comparable值构成的列表可以用List.sort排序；而值可以映射为可比较值的列表，则可以用List.sortBy排序。 如果你需要多级排序（先按一个属性排序，再用另一个属性打破并列），也可以把元组或列表传给List.sortBy，因为元组和列表按字典序排序。

List.sort ["hi", "hello", "bye", "goodbye"]
    --> ["bye", "goodbye", "hello", "hi"]

List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
    --> ["hi", "bye", "hello", "goodbye"]

-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
    --> ["hi", "bye", "dad", "mum", "sis", "hello"]

函数compare接收两个comparable值，返回一个Order。 Order是一种类型，它通过一次操作就能判断一个值是大于（GT）、等于（EQ）还是小于（LT）另一个值。

compare 1 2
    --> LT

compare "" ""
    --> EQ

compare [12] []
    --> GT

可以为任意类型构造比较函数，例如把它传给List.sortWith进行排序：

type Color = Red | Green | Blue

compareColors : Color -> Color -> Order
compareColors a b =
  case (a, b) of
    (Red, Red) -> EQ
    (Red, _) -> LT
    (_, Red) -> GT
    (Green, Green) -> EQ
    (Green, _) -> LT
    (_, Green) -> GT
    (Blue, Blue) -> EQ

List.sortWith compareColors [Blue, Red, Green, Green, Blue]
    --> [Red, Green, Green, Blue, Blue]