ব্লরকেমন কার্ড

তুলনা

সমতা

Elm টাইপগুলো "একই কি না" তা সমতা অপারেটর (==) দিয়ে যাচাই করা যায়। অসমতার অপারেটরটি (/=) (অনেক ভাষার মতো != নয়)। সমতা অপারেটরটি লিটারাল, টাপল, রেকর্ড আর কাস্টম টাইপের ওপর কাজ করে।

1 == 2
    --> False

1 /= 2
    --> True

(1, 2) == (2, 1)
    --> False

type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]

type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings =  (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}

a == b
    --> True

মনে রাখুন, ফাংশন কখনোই তুলনা করা উচিত নয়, কারণ তাহলে প্রোগ্রামটি রানটাইমে ক্র্যাশ করবে।

তুলনাগুলো

তুলনা অপারেটরগুলো (<), (<=), (>), (>=) এবং min, max, compare ফাংশনগুলো comparable টাইপের ওপর কাজ করে। comparable একটি বিশেষ টাইপ, যা তুলনা করা যায় এমন সব বিল্ট-ইন টাইপকে এক জায়গায় করে: সংখ্যা, ক্যারেক্টার, স্ট্রিং, comparable জিনিসের তালিকা এবং comparable জিনিসের টাপল।

1 < 1 + 1
    --> True

'x' < 'X'
    --> False

"abc" < "abz"
    --> True

"abc" < "abcd"
    --> True

"abc" < "b"
    --> True

min [1 , 2, 9000] [10]
    --> [1 , 2, 9000]

min (1, "hello") (3, "bye")
    --> (1, "hello")

রেকর্ড বা কাস্টম টাইপের মতো অন্য টাইপের মান সরাসরি তুলনা করা যায় না।

কিছু বিল্ট-ইন টাইপের ক্ষেত্রে তাদের কনটেন্ট comparable হতে হয়, যেমন Set বা Dict-এর কী (key), কারণ তাদের গঠন একটি অভ্যন্তরীণ ক্রমের ওপর নির্ভর করে।

comparable মানের তালিকা List.sort দিয়ে সাজানো যায়, আর যে মানগুলোকে comparable মানে ম্যাপ করা যায়, সেসব মানের তালিকা List.sortBy দিয়ে সাজানো যায়। আপনার যদি স্তরভিত্তিক সাজানো দরকার হয় (একটি বৈশিষ্ট্য অনুযায়ী সাজানো, আর সমতা থাকলে অন্যটি দিয়ে ভাঙা), তাহলে List.sortBy-এর সাথে টাপল বা তালিকাও ব্যবহার করতে পারেন, কারণ টাপল আর তালিকা লেক্সিকোগ্রাফিক ক্রমে সাজানো হয়।

List.sort ["hi", "hello", "bye", "goodbye"]
    --> ["bye", "goodbye", "hello", "hi"]

List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
    --> ["hi", "bye", "hello", "goodbye"]

-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
    --> ["hi", "bye", "dad", "mum", "sis", "hello"]

compare ফাংশনটি দুটি comparable মান নেয় এবং একটি Order রিটার্ন করে। Order এমন একটি টাইপ, যা একটিমাত্র অপারেশনে দেখে দেয় একটি মান অন্য একটি মানের চেয়ে বড় (GT), সমান (EQ) নাকি ছোট (LT)।

compare 1 2
    --> LT

compare "" ""
    --> EQ

compare [12] []
    --> GT

যেকোনো টাইপের জন্য তুলনা ফাংশন বানিয়ে ব্যবহার করা যায়, যেমন List.sortWith দিয়ে সাজানোর জন্য:

type Color = Red | Green | Blue

compareColors : Color -> Color -> Order
compareColors a b =
  case (a, b) of
    (Red, Red) -> EQ
    (Red, _) -> LT
    (_, Red) -> GT
    (Green, Green) -> EQ
    (Green, _) -> LT
    (_, Green) -> GT
    (Blue, Blue) -> EQ

List.sortWith compareColors [Blue, Red, Green, Green, Blue]
    --> [Red, Green, Green, Blue, Blue]