比較
相等性
Elm 的型別可以用相等運算子(==)來檢查是否「相同」。
不等運算子則是(/=)（不是許多語言裡的!=）。
相等運算子可用於字面值、元組、記錄和自訂型別。
1 == 2
--> False
1 /= 2
--> True
(1, 2) == (2, 1)
--> False
type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]
type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings = (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}
a == b
--> True
請注意，你絕對不該比較函式，因為這會讓程式在執行時崩潰。
大小比較
比較運算子(<)、(<=)、(>)、(>=)以及函式min、max、compare可用於comparable型別。
comparable是一種特殊的型別，它把所有可以互相比較的內建型別歸為一類：數字、字元、字串、由可比較項目組成的陣列，以及由可比較項目組成的元組。
1 < 1 + 1
--> True
'x' < 'X'
--> False
"abc" < "abz"
--> True
"abc" < "abcd"
--> True
"abc" < "b"
--> True
min [1 , 2, 9000] [10]
--> [1 , 2, 9000]
min (1, "hello") (3, "bye")
--> (1, "hello")
其他型別的值，例如記錄或自訂型別，則無法直接比較。
有些內建型別要求其內容必須是comparable，例如Set或Dict的鍵，因為它們的結構依賴內部的排序。
comparable值的陣列可以用List.sort排序；而由可映射為可比較值的值所組成的陣列，則可以用List.sortBy排序。
如果你需要階層式的排序（先依某個屬性排序，再以另一個屬性打破平手），元組或陣列也可以搭配List.sortBy使用，因為元組和陣列是依字典順序排序的。
List.sort ["hi", "hello", "bye", "goodbye"]
--> ["bye", "goodbye", "hello", "hi"]
List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
--> ["hi", "bye", "hello", "goodbye"]
-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
--> ["hi", "bye", "dad", "mum", "sis", "hello"]
函式compare接受兩個comparable值，並回傳一個Order。
Order是一種型別，可以用單一操作判斷某個值是否大於（GT）、等於（EQ）或小於（LT）另一個值。
compare 1 2
--> LT
compare "" ""
--> EQ
compare [12] []
--> GT
我們可以為任意型別建構比較函式，舉例來說，可以搭配List.sortWith來排序：
type Color = Red | Green | Blue
compareColors : Color -> Color -> Order
compareColors a b =
case (a, b) of
(Red, Red) -> EQ
(Red, _) -> LT
(_, Red) -> GT
(Green, Green) -> EQ
(Green, _) -> LT
(_, Green) -> GT
(Blue, Blue) -> EQ
List.sortWith compareColors [Blue, Red, Green, Green, Blue]
--> [Red, Green, Green, Blue, Blue]
學習練習
