ブロルケモンカード

比較

等価性

Elmの型は、等価演算子(==)を使うと「同じかどうか」を調べられます。 非等価演算子は(/=)です（多くの言語の!=とは違います）。 等価演算子は、リテラル、タプル、レコード、カスタム型に対して使えます。

1 == 2
    --> False

1 /= 2
    --> True

(1, 2) == (2, 1)
    --> False

type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]

type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings =  (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}

a == b
    --> True

なお、関数を比較すると実行時にプログラムがクラッシュします。関数の比較は決してしないでください。

大小比較

比較演算子(<)、(<=)、(>)、(>=)と、関数min、max、compareは、comparable型に対して使えます。 comparable型は、比較できる組み込み型をすべてまとめた特別な型です。数値、文字、文字列、comparableな値の配列、comparableな値のタプルが含まれます。

1 < 1 + 1
    --> True

'x' < 'X'
    --> False

"abc" < "abz"
    --> True

"abc" < "abcd"
    --> True

"abc" < "b"
    --> True

min [1 , 2, 9000] [10]
    --> [1 , 2, 9000]

min (1, "hello") (3, "bye")
    --> (1, "hello")

レコードやカスタム型など、それ以外の型の値は直接比較できません。

SetやDictのキーなど、一部の組み込み型では、内容がcomparableである必要があります。これらの構造は内部的な順序に依存しているためです。

comparableな値の配列はList.sortで並べ替えられ、comparableな値に変換できる値の配列はList.sortByで並べ替えられます。 階層的な並べ替え（ある基準で並べ、同じなら別の基準で順序を決める）が必要な場合は、タプルや配列をList.sortByで使うこともできます。タプルと配列は辞書順に並べ替えられるためです。

List.sort ["hi", "hello", "bye", "goodbye"]
    --> ["bye", "goodbye", "hello", "hi"]

List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
    --> ["hi", "bye", "hello", "goodbye"]

-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
    --> ["hi", "bye", "dad", "mum", "sis", "hello"]

関数compareは2つのcomparableな値を受け取り、Orderを返します。 Orderは、ある値が別の値より大きい（GT）、等しい（EQ）、小さい（LT）かを、1回の操作で判定できる型です。

compare 1 2
    --> LT

compare "" ""
    --> EQ

compare [12] []
    --> GT

比較関数は、任意の型に対して作ることができ、たとえばList.sortWithでの並べ替えに使えます。

type Color = Red | Green | Blue

compareColors : Color -> Color -> Order
compareColors a b =
  case (a, b) of
    (Red, Red) -> EQ
    (Red, _) -> LT
    (_, Red) -> GT
    (Green, Green) -> EQ
    (Green, _) -> LT
    (_, Green) -> GT
    (Blue, Blue) -> EQ

List.sortWith compareColors [Blue, Red, Green, Green, Blue]
    --> [Red, Green, Green, Blue, Blue]