Blorkemon 카드

비교

동등성

Elm에서는 동등 연산자 (==)로 타입이 "같은지" 확인할 수 있어요. 부등 연산자는 (/=)예요 (많은 언어의 !=가 아니에요). 동등 연산자는 리터럴, 튜플, 레코드, 커스텀 타입에 사용할 수 있어요.

1 == 2
    --> False

1 /= 2
    --> True

(1, 2) == (2, 1)
    --> False

type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]

type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings =  (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}

a == b
    --> True

함수는 절대 비교하면 안 돼요. 런타임에 프로그램이 크래시 나거든요.

비교

비교 연산자 (<), (<=), (>), (>=)와 함수 min, max, compare는 comparable 타입에서 동작해요. comparable 타입은 비교할 수 있는 모든 내장 타입을 묶은 특별한 타입이에요. 숫자, 문자, 문자열, comparable한 것들의 리스트, comparable한 것들의 튜플이 여기에 속해요.

1 < 1 + 1
    --> True

'x' < 'X'
    --> False

"abc" < "abz"
    --> True

"abc" < "abcd"
    --> True

"abc" < "b"
    --> True

min [1 , 2, 9000] [10]
    --> [1 , 2, 9000]

min (1, "hello") (3, "bye")
    --> (1, "hello")

레코드나 커스텀 타입처럼 다른 타입의 값은 직접 비교할 수 없어요.

Set이나 Dict의 키처럼 일부 내장 타입은 내부 정렬에 의존하기 때문에 내용이 comparable해야 해요.

comparable 값들의 리스트는 List.sort로 정렬할 수 있고, comparable 값으로 매핑할 수 있는 값들의 리스트는 List.sortBy로 정렬할 수 있어요. 여러 단계로 정렬해야 한다면 (한 속성으로 정렬하고, 값이 같으면 다른 속성으로 순서를 정한다면) 튜플이나 리스트도 List.sortBy와 함께 사용할 수 있어요. 튜플과 리스트는 사전순으로 정렬되기 때문이에요.

List.sort ["hi", "hello", "bye", "goodbye"]
    --> ["bye", "goodbye", "hello", "hi"]

List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
    --> ["hi", "bye", "hello", "goodbye"]

-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
    --> ["hi", "bye", "dad", "mum", "sis", "hello"]

compare 함수는 comparable 값 두 개를 받아서 Order를 반환해요. Order는 어떤 값이 다른 값보다 큰지(GT), 같은지(EQ), 작은지(LT)를 한 번의 연산으로 확인하는 타입이에요.

compare 1 2
    --> LT

compare "" ""
    --> EQ

compare [12] []
    --> GT

비교 함수는 임의의 타입에 대해 만들 수 있고, 예를 들어 List.sortWith로 정렬하는 데 사용할 수 있어요:

type Color = Red | Green | Blue

compareColors : Color -> Color -> Order
compareColors a b =
  case (a, b) of
    (Red, Red) -> EQ
    (Red, _) -> LT
    (_, Red) -> GT
    (Green, Green) -> EQ
    (Green, _) -> LT
    (_, Green) -> GT
    (Blue, Blue) -> EQ

List.sortWith compareColors [Blue, Red, Green, Green, Blue]
    --> [Red, Green, Green, Blue, Blue]