Порівняння
Рівність
Типи Elm можна перевірити на «однаковість» за допомогою оператора рівності (==).
Оператор нерівності має вигляд (/=) (не !=, як у багатьох мовах).
Оператор рівності працює з літералами, кортежами, записами та власними типами.
1 == 2
--> False
1 /= 2
--> True
(1, 2) == (2, 1)
--> False
type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]
type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings = (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}
a == b
--> True
Зауважмо, що функції ніколи не слід порівнювати, бо це призведе до аварійного завершення програми під час виконання.
Операції порівняння
Оператори порівняння (<), (<=), (>), (>=) і функції min, max, compare працюють із типами comparable.
Тип comparable - це особливий тип, який обʼєднує всі вбудовані типи, які можна порівнювати: числа, символи, рядки тексту (англ. string), масиви порівнюваних значень і кортежі порівнюваних значень.
1 < 1 + 1
--> True
'x' < 'X'
--> False
"abc" < "abz"
--> True
"abc" < "abcd"
--> True
"abc" < "b"
--> True
min [1 , 2, 9000] [10]
--> [1 , 2, 9000]
min (1, "hello") (3, "bye")
--> (1, "hello")
Значення інших типів, як-от записів чи власних типів, не можна порівнювати безпосередньо.
Деякі вбудовані типи вимагають, щоб їхній вміст був comparable, наприклад ключі Set чи Dict, оскільки їхня структура спирається на внутрішнє впорядкування.
Масиви comparable-значень можна сортувати за допомогою List.sort, а масиви значень, які можна перетворити на порівнювані значення, за допомогою List.sortBy.
Якщо потрібне ієрархічне сортування (сортувати за однією властивістю, а однакові значення впорядковувати за іншою), кортежі чи масиви теж можна використовувати з List.sortBy, оскільки кортежі й масиви сортуються в лексикографічному порядку.
List.sort ["hi", "hello", "bye", "goodbye"]
--> ["bye", "goodbye", "hello", "hi"]
List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
--> ["hi", "bye", "hello", "goodbye"]
-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
--> ["hi", "bye", "dad", "mum", "sis", "hello"]
Функція compare приймає два comparable-значення і повертає Order.
Order - це тип, який за одну операцію перевіряє, чи значення більше (GT), рівне (EQ) або менше (LT) за інше.
compare 1 2
--> LT
compare "" ""
--> EQ
compare [12] []
--> GT
Функції порівняння можна побудувати для довільних типів і використовувати, наприклад, для сортування за допомогою List.sortWith:
type Color = Red | Green | Blue
compareColors : Color -> Color -> Order
compareColors a b =
case (a, b) of
(Red, Red) -> EQ
(Red, _) -> LT
(_, Red) -> GT
(Green, Green) -> EQ
(Green, _) -> LT
(_, Green) -> GT
(Blue, Blue) -> EQ
List.sortWith compareColors [Blue, Red, Green, Green, Blue]
--> [Red, Green, Green, Blue, Blue]
Навчальна вправа
