Κάρτες Blorkemon

Σύγκριση

Ισότητα

Οι τύποι της Elm μπορούν να ελεγχθούν για το αν "είναι ίδιοι" με τον τελεστή ισότητας (==). Ο τελεστής ανισότητας είναι το (/=) (όχι το != όπως σε πολλές γλώσσες). Ο τελεστής ισότητας λειτουργεί σε literals, πλειάδες, καταγραφές και προσαρμοσμένους τύπους.

1 == 2
    --> False

1 /= 2
    --> True

(1, 2) == (2, 1)
    --> False

type alias MyRecord = { myInt : Int, myStrings : List String }
a : MyRecord
a = MyRecord (1 + 1) ["hello world"]

type alias MyOtherRecord = { myInt : Int, myStrings : List String }
myStrings =  (String.join " " ["hello", "world"]) :: []
b : MyOtherRecord
b = { myInt = 2, myStrings = myStrings}

a == b
    --> True

Σημείωσε ότι δεν πρέπει ποτέ να συγκρίνεις συναρτήσεις, γιατί αυτό θα κάνει το πρόγραμμα να καταρρεύσει κατά την εκτέλεση.

Συγκρίσεις

Οι τελεστές σύγκρισης (<), (<=), (>), (>=) και οι συναρτήσεις min, max, compare λειτουργούν σε τύπους comparable. Ο τύπος comparable είναι ένας ειδικός τύπος που ομαδοποιεί όλους τους ενσωματωμένους τύπους που μπορούν να συγκριθούν: αριθμούς, χαρακτήρες, συμβολοσειρές, λίστες από συγκρίσιμα πράγματα και πλειάδες από συγκρίσιμα πράγματα.

1 < 1 + 1
    --> True

'x' < 'X'
    --> False

"abc" < "abz"
    --> True

"abc" < "abcd"
    --> True

"abc" < "b"
    --> True

min [1 , 2, 9000] [10]
    --> [1 , 2, 9000]

min (1, "hello") (3, "bye")
    --> (1, "hello")

Τιμές άλλων τύπων, όπως οι καταγραφές ή οι προσαρμοσμένοι τύποι, δεν μπορούν να συγκριθούν απευθείας.

Κάποιοι ενσωματωμένοι τύποι απαιτούν το περιεχόμενό τους να είναι comparable, όπως τα κλειδιά των Set ή Dict, αφού η δομή τους βασίζεται σε μια εσωτερική διάταξη.

Οι λίστες με comparable τιμές μπορούν να ταξινομηθούν με το List.sort και οι λίστες με τιμές που μπορούν να αντιστοιχιστούν σε συγκρίσιμες τιμές μπορούν να ταξινομηθούν με το List.sortBy. Αν χρειάζεσαι ιεραρχική ταξινόμηση (ταξινόμηση με βάση μία ιδιότητα και λύση των ισοπαλιών με μια άλλη), μπορείς να χρησιμοποιήσεις πλειάδες ή λίστες με το List.sortBy, αφού οι πλειάδες και οι λίστες ταξινομούνται με λεξικογραφική σειρά.

List.sort ["hi", "hello", "bye", "goodbye"]
    --> ["bye", "goodbye", "hello", "hi"]

List.sortBy String.length ["hi", "hello", "bye", "goodbye"]
    --> ["hi", "bye", "hello", "goodbye"]

-- sort by length, then alphabetically
List.sortBy (\str -> (String.length str, str)) ["hi", "mum", "hello", "sis", "bye", "dad"]
    --> ["hi", "bye", "dad", "mum", "sis", "hello"]

Η συνάρτηση compare παίρνει δύο comparable τιμές και επιστρέφει ένα Order. Ένα Order είναι ένας τύπος που ελέγχει με μία μόνο πράξη αν μια τιμή είναι μεγαλύτερη (GT), ίση (EQ) ή μικρότερη (LT) από μια άλλη.

compare 1 2
    --> LT

compare "" ""
    --> EQ

compare [12] []
    --> GT

Μπορείς να κατασκευάσεις συναρτήσεις σύγκρισης για οποιουσδήποτε τύπους και να τις χρησιμοποιήσεις, για παράδειγμα, για ταξινόμηση με το List.sortWith:

type Color = Red | Green | Blue

compareColors : Color -> Color -> Order
compareColors a b =
  case (a, b) of
    (Red, Red) -> EQ
    (Red, _) -> LT
    (_, Red) -> GT
    (Green, Green) -> EQ
    (Green, _) -> LT
    (_, Green) -> GT
    (Blue, Blue) -> EQ

List.sortWith compareColors [Blue, Red, Green, Green, Blue]
    --> [Red, Green, Green, Blue, Blue]