正则聊天机器人

正则表达式是一种用途非常广泛的_模式匹配_字符串的方式，它使用的是一门专门为此设计的领域特定语言（DSL）。

和另外几门编程语言一样，Julia 并没有尝试自己实现一套正则表达式库。它选择封装广受欢迎的 PCRE2 库，因此提供的正则语法与（例如）Gleam 完全相同，也与 JavaScript 非常接近。

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

Julia 的正则表达式接口在手册中有详细说明。

在 Julia 中，正则表达式就是一个字符串，只是在开头的"之前加了个r。所有基本功能都属于标准库的一部分。

事实上，Strings概念中已经讨论过的许多函数，本身就支持正则搜索，例如occursin()。

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

修饰符字符可以跟在结尾引号后面，例如用i进行不区分大小写的匹配。

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

捕获

通常，我们想知道_到底_匹配了什么。做法是在正则表达式中用括号加入捕获组，然后使用match()函数。

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

当然，匹配也可能失败。这时结果会是特殊值Nothing，而不是RegexMatch，所以要准备好对此进行判断。

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

match默认从字符串开头开始匹配，不过我们也可以指定一个偏移量n，忽略前n个字符。

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

在 Julia 中，match()只会找到目标字符串里的_第一个_匹配项：不像某些语言那样有全局修饰符。

取而代之的是eachmatch()，它返回一个匹配项的迭代器。它是惰性求值的，所以你可能需要把它转换成你想要的格式。

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

替换

使用正则的一个常见原因，是把匹配到的内容替换成另一个字符串。

replace()函数在Strings概念中讨论过，当时用的是字符串字面量来搜索。同一个函数也可以充分发挥正则匹配的全部威力。

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

上面的第二个例子展示了，在s" "字符串里，编号捕获组和命名捕获组都可以用在替换中。

更多细节请参阅手册：这个话题总是逼着大多数程序员反复回去翻文档！