Reguláris chatbot

A reguláris kifejezések sokoldalú eszközt nyújtanak a stringek mintaillesztésére, egy erre a célra tervezett domain-specifikus nyelv (DSL) segítségével.

Ahogy sok más programozási nyelv, a Julia sem próbál saját regexkönyvtárat megvalósítani. Ehelyett a népszerű PCRE2 könyvtárat csomagolja be, így a regex szintaxisa megegyezik például a Gleamével, és nagyon hasonlít a Javascriptéhez.

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

A Julia reguláris kifejezésekhez kapcsolódó felületét a kézikönyv írja le.

A reguláris kifejezés a Juliában egyszerűen egy string, amelyet a nyitó " előtt egy r előz meg. Az összes alapvető funkció a standard könyvtár része.

Valójában a Strings fogalomban már tárgyalt függvények közül sok eleve regexes keresésre készült, például az occursin().

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

A záró idézőjel után módosító karakterek állhatnak, például az i a kis- és nagybetűt nem megkülönböztető illesztéshez.

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

Elfogó csoportok

Gyakran szeretnénk tudni, hogy mi illeszkedik. Ezt úgy érhetjük el, hogy elfogó csoportokat teszünk zárójelbe a regexen belül, majd a match() függvényt használjuk.

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

Az illesztés persze sikertelen is lehet. Ilyenkor az eredmény a RegexMatch helyett a speciális Nothing érték lesz, ezért készülj fel ennek ellenőrzésére.

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

Bár a match alapértelmezés szerint a string elejétől indul, megadhatunk egy n eltolást is, hogy figyelmen kívül hagyjuk az első n karaktert.

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

A Juliában a match() csak az első illeszkedést találja meg a cél stringben: nincs globális módosító, mint néhány más nyelvben.

Ehelyett ott van az eachmatch(), amely az illeszkedések egy iterátorát adja vissza. Ez lusta kiértékelésű, ezért lehet, hogy a kívánt formátumba kell alakítanod.

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

Csere

A regex használatának egyik gyakori oka, hogy az illeszkedést egy másik stringre cseréljük.

A replace() függvényt a Strings fogalomban már tárgyaltuk, ahol stringliterálokra kerestünk vele. Ugyanez a függvény ki tudja használni a regexes illesztés teljes erejét.

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

A fenti második példa megmutatja, hogyan használhatók a sorszámozott és a nevesített elfogó csoportok is a helyettesítésben, egy s" " stringen belül.

További részletekért lásd a kézikönyvet: ez egy olyan téma, amely folyton visszatereli a legtöbb programozót a dokumentációhoz!