রেগুলার চ্যাটবট

রেগুলার এক্সপ্রেশন হলো স্ট্রিং প্যাটার্ন ম্যাচ করার একটি অত্যন্ত বহুমুখী উপায়, যার জন্য এ কাজের জন্যই বিশেষভাবে তৈরি একটি ডোমেইন স্পেসিফিক ভাষা (DSL) ব্যবহার করা হয়।

অন্যান্য অনেক প্রোগ্রামিং ভাষার মতো জুলিয়া নিজস্ব রেগেক্স লাইব্রেরি তৈরি করার কোনো চেষ্টা করে না। বরং এটি জনপ্রিয় PCRE2 লাইব্রেরিকে ঘিরে তৈরি, ফলে যে রেগেক্স সিনট্যাক্স পাওয়া যায় তা (উদাহরণস্বরূপ) Gleam-এর মতোই এবং Javascript-এর সাথে খুব কাছাকাছি।

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

জুলিয়ায় রেগুলার এক্সপ্রেশনের ইন্টারফেস নিয়ে আলোচনা করা হয়েছে ম্যানুয়ালে।

জুলিয়ায় একটি রেগুলার এক্সপ্রেশন আসলে একটি সাধারণ স্ট্রিং, যার সামনে শুরুর "-এর আগে একটি r বসানো থাকে। এর সব বেসিক ফাংশনালিটি স্ট্যান্ডার্ড লাইব্রেরির অংশ।

আসলে Strings কনসেপ্টে আগেই আলোচনা করা অনেক ফাংশনই মূলত রেগেক্স সার্চের জন্য তৈরি, যেমন occursin().

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

ক্লোজিং কোটের পরে মডিফায়ার ক্যারেক্টার বসতে পারে, যেমন বড়-ছোট হাতের অক্ষরের পার্থক্য না ধরে ম্যাচ করার জন্য i.

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

ক্যাপচার

সাধারণত আমরা জানতে চাই কী ম্যাচ করেছে। এর জন্য রেগেক্সের ভেতরে বন্ধনীর মধ্যে ক্যাপচার গ্রুপ রাখতে হয়, তারপর match() ফাংশন ব্যবহার করতে হয়।

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

অবশ্যই, ম্যাচ ব্যর্থ হতে পারে। তখন ফলাফল হিসেবে RegexMatch-এর বদলে বিশেষ মান Nothing পাওয়া যাবে, তাই এটি পরীক্ষা করার জন্য প্রস্তুত থাকুন।

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

match ডিফল্টভাবে স্ট্রিংয়ের শুরু থেকে খোঁজা শুরু করে, তবে আমরা একটি অফসেট n-ও দিতে পারি, যাতে প্রথম nটি ক্যারেক্টার বাদ দেওয়া হয়।

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

জুলিয়ায় match() টার্গেট স্ট্রিংয়ের ভেতরে শুধু প্রথম ম্যাচটিই খুঁজে বের করে: অন্য কিছু ভাষার মতো গ্লোবাল মডিফায়ার এখানে নেই।

এর বদলে আছে eachmatch(), যা ম্যাচগুলোর একটি ইটারেটর রিটার্ন করে। এটি লেজিভাবে ইভালুয়েট হয়, তাই আপনার পছন্দের ফরম্যাটে রূপান্তর করার প্রয়োজন হতে পারে।

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

প্রতিস্থাপন

রেগেক্স ব্যবহারের একটি কমন কারণ হলো ম্যাচটি ভিন্ন একটি স্ট্রিং দিয়ে প্রতিস্থাপন করা।

Strings কনসেপ্টে replace() ফাংশন নিয়ে আলোচনা করা হয়েছিল, যেখানে খোঁজার জন্য স্ট্রিং লিটারেল ব্যবহার করা হয়। একই ফাংশন রেগেক্স ম্যাচিংয়ের পূর্ণ শক্তি কাজে লাগাতে পারে।

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

উপরের দ্বিতীয় উদাহরণটি দেখায় যে একটি s" " স্ট্রিংয়ের ভেতরে প্রতিস্থাপনে নাম্বারযুক্ত ও নামযুক্ত, দুই ধরনের ক্যাপচার গ্রুপই ব্যবহার করা যায়।

আরও বিস্তারিত জানতে ম্যানুয়াল দেখুন: এই বিষয়টি এমন যে বেশিরভাগ প্রোগ্রামারকে বারবার ডকুমেন্টেশনে ফিরে যেতে বাধ্য করে!