正規表現チャットボット

正規表現は、文字列の_パターンマッチング_を行うための非常に汎用性の高い方法で、そのために設計されたドメイン固有言語（DSL）を使います。

他の多くのプログラミング言語と同じく、Juliaは独自の正規表現ライブラリを実装しようとはしません。その代わり、広く使われているPCRE2ライブラリをラップしており、その結果、（例えば）Gleamとまったく同じ、JavaScriptとよく似た正規表現の構文を提供します。

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

Juliaの正規表現へのインターフェースについては、マニュアルで説明されています。

Juliaの正規表現は、開き"の前にrを付けた文字列にすぎません。基本的な機能はすべて標準ライブラリに含まれています。

実際、Stringsのコンセプトですでに扱った関数の多くは、occursin()のように、標準で正規表現検索を想定して設計されています。

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

終わりの引用符のあとには修飾子を付けられます。たとえば、大文字と小文字を区別しないマッチにはiを使います。

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

キャプチャ

たいていの場合、_何が_マッチしたのかを知りたいはずです。それには、正規表現の中に括弧でキャプチャグループを含めて、match()関数を使います。

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

もちろん、マッチは失敗することもあります。その場合、結果はRegexMatchではなく特別な値Nothingになるので、それに備えてテストできるようにしておきましょう。

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

matchはデフォルトでは文字列の先頭から検索を始めますが、オフセットnを指定して最初のn文字を無視することもできます。

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

Juliaでは、match()は対象の文字列の中で_最初_のマッチしか見つけません。一部の言語にあるようなグローバル修飾子はありません。

代わりに、eachmatch()があり、これはマッチのイテレーターを返します。遅延評価されるので、目的の形式に変換する必要があるかもしれません。

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

置換

正規表現を使うよくある理由の一つは、マッチした部分を別の文字列に置き換えることです。

replace()関数は、Stringsのコンセプトで、文字列リテラルを検索対象として扱う形で説明しました。同じ関数で、正規表現マッチングの力を存分に引き出せます。

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

上の2つ目の例は、s" "文字列の中で、番号付きと名前付きの両方のキャプチャグループを置換に使えることを示しています。

詳しくはマニュアルを参照してください。これは、ほとんどのプログラマーがいつもドキュメントに戻らされてしまうトピックです！