روبوت المحادثة النمطي

التعبيرات النمطية طريقة بالغة التنوع من أجل مطابقة الأنماط في السلاسل النصية، وذلك باستخدام لغة خاصة بالمجال (DSL) مصممة لهذا الغرض.

على غرار عدة لغات برمجة أخرى، لا تحاول Julia تنفيذ مكتبة Regex خاصة بها. بدلًا من ذلك، تستعمل مكتبة PCRE2 الشائعة كغلاف، فتوفّر بذلك صياغة Regex مطابقة تمامًا لصياغة Gleam (على سبيل المثال)، وشديدة الشبه بـ Javascript.

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

تُوصَف واجهة Julia مع التعبيرات النمطية في الدليل.

التعبير النمطي في Julia هو ببساطة سلسلة نصية تسبقها r قبل علامة " الافتتاحية. وكل الوظائف الأساسية جزء من المكتبة القياسية.

في الواقع، كثير من الدوال التي جرت مناقشتها بالفعل في مفهوم Strings مصممة أصلًا لعمليات بحث Regex، مثل occursin().

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

يمكن أن تتبع أحرف التعديل علامة التنصيص الختامية، مثل i من أجل مطابقة غير حساسة لحالة الأحرف.

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

الالتقاط

غالبًا ما نريد معرفة ما الذي يطابق. ويتحقق ذلك بتضمين مجموعات التقاط بين قوسين هلاليين داخل التعبير النمطي، ثم استخدام الدالة match().

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

بطبيعة الحال، قد تفشل المطابقات. وعندئذ تكون النتيجة القيمة الخاصة Nothing بدلًا من RegexMatch، فكن مستعدًا لاختبار ذلك.

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

ورغم أن match تبدأ افتراضيًا من بداية السلسلة النصية، يمكننا أيضًا تحديد إزاحة n لتجاهل أول n من الأحرف.

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

في Julia، لن تجد match() سوى المطابقة الأولى داخل السلسلة النصية المستهدفة: فلا يوجد معدِّل شامل كما في بعض اللغات الأخرى.

بدلًا من ذلك، لدينا eachmatch()، التي تُرجع مكرِّرًا للمطابقات. ويُقيَّم هذا بتكاسل، لذا قد تحتاج إلى تحويله إلى الصيغة التي تريدها.

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

الاستبدال

من الأسباب الشائعة لاستخدام Regex استبدال المطابقة بسلسلة نصية مختلفة.

جرت مناقشة الدالة replace() في مفهوم Strings، حيث كانت تستخدم سلاسل نصية حرفية للبحث بها. ويمكن للدالة نفسها أن تستفيد من كامل قوة مطابقة Regex.

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

يوضح المثال الثاني أعلاه كيف يمكن استخدام مجموعات الالتقاط المرقّمة والمسمّاة معًا في الاستبدال، داخل سلسلة نصية s" ".

راجع الدليل لمزيد من التفاصيل: فهذا موضوع يعيد معظم المبرمجين باستمرار إلى الوثائق!