Le espressioni regolari sono un modo estremamente versatile per fare pattern matching sulle stringhe, usando un linguaggio specifico del dominio (DSL) progettato proprio per questo scopo.
Come diversi altri linguaggi di programmazione, Julia non cerca di implementare una propria libreria di regex. Si limita invece a incapsulare la popolare libreria PCRE2, offrendo così una sintassi delle regex identica a quella di (per esempio) Gleam e molto simile a quella di Javascript.
Questo programma di studio di Julia presuppone che tu abbia già familiarità con la sintassi di base delle regex.
Ci concentreremo esclusivamente sulle funzionalità specifiche di Julia.
Qui sotto sono elencate alcune risorse per ripassare le espressioni regolari.
L'interfaccia di Julia alle espressioni regolari è descritta nel manuale.
In Julia, un'espressione regolare è semplicemente una stringa preceduta da r prima della " di apertura. Tutte le funzionalità di base fanno parte della libreria standard.
In realtà, molte delle funzioni già presentate nel concetto Strings sono pensate per le ricerche con le regex, come occursin().
julia> re = r"test$"
r"test$"
julia> typeof(re)
Regex
# Does a string end with "test"?
julia> occursin(re, "this is a test")
true
julia> occursin(re, "these are tests")
false
Dopo la virgoletta di chiusura possono seguire caratteri modificatori, come i per una corrispondenza che non distingue maiuscole e minuscole.
julia> occursin(r"test", "Testing")
false
julia> occursin(r"test"i, "Testing")
true
Gruppi di cattura
Spesso vogliamo sapere cosa corrisponde. Per farlo, si includono dei gruppi di cattura tra parentesi all'interno della regex e poi si usa la funzione match().
julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")
julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
"25g"
"200ml"
# how many matches?
julia> length(m.captures)
2
# what matched?
julia> m[1], m[2]
("25g", "200ml")
# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
10
23
Naturalmente, le corrispondenze possono fallire. In quel caso il risultato sarà il valore speciale Nothing invece di un RegexMatch, quindi preparati a verificarlo.
# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")
julia> typeof(m)
Nothing
julia> isnothing(m)
true
Anche se match parte per impostazione predefinita dall'inizio della stringa, possiamo anche specificare un offset n per ignorare i primi n caratteri.
# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")
# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")
In Julia, match() trova solo la prima corrispondenza nella stringa di destinazione: non esiste un modificatore globale come in altri linguaggi.
Abbiamo invece eachmatch(), che restituisce un iteratore di corrispondenze. La valutazione è pigra, quindi potresti doverlo convertire nel formato che ti serve.
julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)
# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
RegexMatch("cat", 1="cat")
RegexMatch("sat", 1="sat")
RegexMatch("mat", 1="mat")
# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
"cat"
"sat"
"mat"
# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
"cat"
"sat"
"mat"
Sostituire
Un motivo comune per usare una regex è sostituire la corrispondenza con una stringa diversa.
La funzione replace() è stata presentata nel concetto Strings, con l'uso di stringhe letterali come criteri di ricerca. La stessa funzione può sfruttare tutta la potenza delle corrispondenze regex.
julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"
julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"
Il secondo esempio qui sopra mostra come si possano usare nella sostituzione sia i gruppi di cattura numerati sia quelli con nome, all'interno di una stringa s" ".
Consulta il manuale per maggiori dettagli: è un argomento che riporta continuamente la maggior parte dei programmatori alla documentazione!
Esercizio di apprendimento
