正規聊天機器人

正規表達式是一種非常靈活的字串「模式比對」方式，它使用一套專為此目的設計的領域特定語言（DSL）。

就像其他幾種程式語言一樣，Julia 並不打算自己實作正規表達式函式庫。 它改為包裝廣受使用的 PCRE2 函式庫，因此提供了與（例如）Gleam 完全相同、並與 JavaScript 非常相似的正規表達式語法。

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

Julia 的正規表達式介面在手冊中有說明。

Julia 的正規表達式就只是一個字串，只是在開頭的"前面多了r。 所有基本功能都屬於標準函式庫的一部分。

事實上，Strings概念中介紹過的許多函式，本身就設計用來進行正規表達式搜尋，例如occursin()。

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

修飾字元可以接在結尾引號的後面，例如i代表忽略大小寫的比對。

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

擷取

我們通常想知道究竟是「什麼」符合。做法是在正規表達式裡用括號加入擷取群組，再使用match()函式。

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

當然，比對也可能失敗。 這時結果會是特殊值Nothing，而不是RegexMatch，所以要準備好檢查這種情況。

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

雖然match預設從字串開頭開始比對，我們也可以指定位移量n，忽略前n個字元。

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

在 Julia 中，match()只會找出目標字串裡的「第一個」比對：不像某些其他語言那樣有全域修飾字元。

取而代之的是eachmatch()，它會回傳一個比對的迭代器。 它是惰性求值的，所以你可能需要將它轉成你想要的格式。

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

取代

使用正規表達式的常見原因之一，就是把比對到的內容換成另一個字串。

replace()函式在Strings概念中已經討論過，當時是用字串常值來搜尋。 同一個函式也能發揮正規表達式比對的全部威力。

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

上面的第二個例子展示了編號擷取群組和具名擷取群組都能用在取代內容中，而且是在s" "字串裡。

更多細節請見手冊：這個主題總是逼著大多數程式設計師一再回頭翻文件！