چت‌بات باقاعده

«عبارات باقاعده» روشی بسیار انعطاف‌پذیر برای تطبیق الگو روی رشته‌ها هستند که از یک زبان دامنه‌ویژه (DSL) طراحي‌شده برای همین منظور استفاده می‌کنند.

Julia هم مانند چندین زبان برنامه‌نویسی دیگر تلاشی نمی‌کند که کتابخانه‌ی Regex خودش را پیاده‌سازی کند. در عوض، کتابخانه‌ی پرکاربرد PCRE2 را در بر می‌گیرد و بدین ترتیب نحوه‌ی نگارش Regex یکسانی با (برای مثال) Gleam و بسیار شبیه به Javascript ارائه می‌دهد.

• Regex101
• RegExr
• RexEgg
• RegexOne
• Regular Expressions Info

رابط Julia با عبارات باقاعده در راهنما توضیح داده شده است.

یک عبارت باقاعده در Julia به سادگی رشته‌ای است که پیش از " آغازین، یک r دارد. همه‌ی قابلیت‌های پایه بخشی از کتابخانه‌ی استاندارد هستند.

در واقع، بسیاری از توابعی که پیش‌تر در مفهوم Strings بررسی کردیم، به‌طور پیش‌فرض برای جست‌وجوهای Regex طراحی شده‌اند، مانند occursin().

julia> re = r"test$"
r"test$"

julia> typeof(re)
Regex

# Does a string end with "test"?
julia> occursin(re, "this is a test")
true

julia> occursin(re, "these are tests")
false

نویسه‌های اصلاح‌کننده می‌توانند پس از نقل‌قول پایانی بیایند، مانند i برای تطبیق بدون حساسیت به بزرگی و کوچکی حروف.

julia> occursin(r"test", "Testing")
false

julia> occursin(r"test"i, "Testing")
true

گروه‌های ثبت

معمولاً می‌خواهیم بدانیم چه چیزی تطبیق می‌یابد. این کار با قرار دادن گروه‌های ثبت داخل پرانتز در عبارت باقاعده و سپس استفاده از تابع match() انجام می‌شود.

julia> m = match(r"(\d+g) .* (\d+ml)", "dissolve 25g sugar in 200ml water")
RegexMatch("25g sugar in 200ml", 1="25g", 2="200ml")

julia> m.captures
2-element Vector{Union{Nothing, SubString{String}}}:
 "25g"
 "200ml"

# how many matches?
julia> length(m.captures)
2

# what matched?
julia> m[1], m[2]
("25g", "200ml")

# Starting positions of the matches (character index)
julia> m.offsets
2-element Vector{Int64}:
 10
 23

البته ممکن است تطبیق‌ها شکست بخورند. در این صورت، نتیجه به‌جای RegexMatch مقدار ویژه‌ی Nothing خواهد بود، پس آماده باشید که این حالت را بررسی کنید.

# failed match
m = match(r"(not here)", "dissolve 25g sugar in 200ml water")

julia> typeof(m)
Nothing

julia> isnothing(m)
true

هرچند match به‌طور پیش‌فرض از ابتدای رشته شروع می‌کند، می‌توانیم یک جابه‌جایی n هم مشخص کنیم تا از n نویسه‌ی اول صرف‌نظر شود.

# capture first match
julia> m = match(r"(\wat)", "cat, sat, mat")
RegexMatch("cat", 1="cat")

# ignore first 5 characters, then match
julia> m = match(r"(\wat)", "cat, sat, mat", 5)
RegexMatch("sat", 1="sat")

در Julia، match() فقط نخستین تطبیق را در رشته‌ی هدف پیدا می‌کند: هیچ اصلاح‌کننده‌ی سراسری مانند برخی زبان‌های دیگر وجود ندارد.

در عوض، eachmatch() را داریم که یک تکرارگر از تطبیق‌ها برمی‌گرداند. این تکرارگر به‌صورت تنبل ارزیابی می‌شود، بنابراین ممکن است لازم باشد آن را به قالب دلخواه‌تان تبدیل کنید.

julia> matches = eachmatch(r"(\wat)", "cat, sat, mat")
Base.RegexMatchIterator{String}(r"(\wat)", "cat, sat, mat", false)

# convert to vector
julia> collect(matches)
3-element Vector{RegexMatch}:
 RegexMatch("cat", 1="cat")
 RegexMatch("sat", 1="sat")
 RegexMatch("mat", 1="mat")

# convert with comprehension
julia> [m.match for m in matches]
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

# broadcast an anonymous function
julia> (m -> m.match).(matches)
3-element Vector{SubString{String}}:
 "cat"
 "sat"
 "mat"

جایگزینی

یکی از دلایل رایج استفاده از Regex، جایگزین کردن تطبیق با رشته‌ای دیگر است.

تابع replace() در مفهوم Strings بررسی شد، آن‌جا که از رشته‌های متنی برای جست‌وجو استفاده می‌کردیم. همین تابع می‌تواند از تمام توان تطبیق Regex بهره ببرد.

julia> replace("some string", r"[aeiou]" => "*")
"s*m* str*ng"

julia> replace("first second", r"(\w+) (?<agroup>\w+)" => s"\g<agroup> \1")
"second first"

مثال دوم بالا نشان می‌دهد که چگونه هم گروه‌های ثبت شماره‌دار و هم گروه‌های ثبت نام‌دار می‌توانند در جایگزینی، داخل یک رشته‌ی s" "، به کار روند.

برای جزئیات بیشتر راهنما را ببینید: این موضوعی است که پیوسته بیشتر برنامه‌نویسان را به مستندات برمی‌گرداند!