关键字列表是由 {key, value}元组组成的列表。关键字列表有两种写法:
# concise
[month: "April", year: 2018]
# explicit
[{:month, "April"}, {:year, 2018}]
并非每个二元组组成的列表都是关键字列表。键必须是原子:
Keyword.keyword?([{"month", "April"}])
# => false
如果你想在键里使用字母、数字和 _ 以外的字符,就需要用引号把它包起来。不过,这并不会让它变成字符串,它仍然是原子。
Keyword.keyword?(["day of week": "Monday"])
# => true
关键字列表里的键可以重复,并且键值对是有序的。当你想获取某个键下的单个值时,拿到的是第一个值,同一个键下的其他值会被静默忽略。
list = [month: "April", month: "May"]
Keyword.get_values(list, :month)
# => ["April", "May"]
Keyword.get(list, :month)
# => "April"
关键字列表也支持Access 行为。
list[:month]
# => "April"
关键字列表的这些特性,使它成为 Elixir 中向函数传递选项的默认机制。
在学习 if 时,你见过一种特殊的简写语法:
if age >= 16, do: "beer", else: "no beer"
这看起来像是 if 接受两个实参,但 do: 和 else: 这一对其实是一个实参,也就是一个关键字列表。同一段代码也可以写成:
if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]
把关键字列表用作函数选项的用法太常见了,所以 Elixir 允许你在关键字列表作为最后一个实参传给函数时省略方括号。
在 Elixir 语法中,元组、列表、映射等的书写方式与函数调用相同,所以它们也能享受这一特性。
[1, 2, three: 3]
# => [1, 2, {:three, 3}]
想用简写语法成功地对关键字列表进行模式匹配,就必须按正确的顺序写出所有的键。因此,处理关键字列表时很少选择模式匹配。这时请改用 Keyword 模块或Access 行为。
[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
| 关键字列表 | 映射 | |
|---|---|---|
| 键的类型 | 原子 | 任意类型,可以在同一个映射里混用 |
| 重复的键 | 是 | 否 |
| 键有序 | 是 | 否 |
| 访问 |
list[:key]、Keyword.get/2
|
map.key、map[:key]、Map.get/2
|
| 访问时间 | 线性 | 对数 |
| 模式匹配 | 不太实用 | 实用 |
更快的访问速度、灵活的键类型和实用的模式匹配,让映射在大多数情况下成为默认选择。
当你数据不多,但需要重复的键或者特定顺序的键时,就用关键字列表。