Список ключових слів - це список кортежів {key, value}. Є два способи записати список ключових слів:
# concise
[month: "April", year: 2018]
# explicit
[{:month, "April"}, {:year, 2018}]
Не кожен список двоелементних кортежів є списком ключових слів. Ключі мають бути атомами:
Keyword.keyword?([{"month", "April"}])
# => false
Якщо в ключі потрібні символи, відмінні від літер, цифр і _, його треба взяти в лапки. Проте це не робить його рядком тексту (англ. string) - це все ще атом.
Keyword.keyword?(["day of week": "Monday"])
# => true
Ключі в списку ключових слів можуть повторюватися, а пари ключ-значення впорядковані. Коли ми намагаємося отримати одне значення за певним ключем, ми отримаємо перше значення, а решту значень за тим самим ключем буде мовчки проігноровано.
list = [month: "April", month: "May"]
Keyword.get_values(list, :month)
# => ["April", "May"]
Keyword.get(list, :month)
# => "April"
Списки ключових слів також підтримують поведінку Access.
list[:month]
# => "April"
Завдяки своїм особливостям списки ключових слів стали типовим механізмом передавання опцій у функції в Elixir.
Коли ми вивчали if, ми бачили спеціальний коротший синтаксис:
if age >= 16, do: "beer", else: "no beer"
Може здатися, що if приймає два аргументи, але пара do: та else: насправді є одним аргументом - списком ключових слів. Той самий код можна записати так:
if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]
Використання списків ключових слів як опцій функцій настільки поширене, що Elixir дозволяє пропустити квадратні дужки, коли список ключових слів є останнім аргументом, переданим у функцію.
Оскільки кортежі, списки, мапи та інші структури в синтаксисі Elixir обробляються так само, як виклики функцій, ця особливість доступна й для них.
[1, 2, three: 3]
# => [1, 2, {:three, 3}]
Щоб успішно зіставити список ключових слів зі зразком за допомогою короткого синтаксису, нам доведеться вказати всі ключі в правильному порядку. Через це зіставлення зі зразком навряд чи варто обирати для роботи зі списками ключових слів. Натомість скористаймося модулем Keyword або поведінкою Access.
[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
| Список ключових слів | Мапа | |
|---|---|---|
| Тип ключа | Атоми | Будь-який, можна змішувати в одній мапі |
| Повторювані ключі | Так | Ні |
| Порядок ключів | Зберігається | Не зберігається |
| Доступ |
list[:key], Keyword.get/2
|
map.key, map[:key], Map.get/2
|
| Час доступу | Лінійний | Логарифмічний |
| Зіставлення зі зразком | Не дуже корисне | Корисне |
Швидший час доступу, гнучкий тип ключа та корисне зіставлення зі зразком роблять мапи типовим вибором у більшості випадків.
Використовуймо списки ключових слів, коли даних небагато, але потрібні повторювані ключі або ключі в певному порядку.