Διαδρομές
/
Elixir
Elixir
/
Ύλη
/
Λίστες λέξεων-κλειδιών
Λί

Λίστες λέξεων-κλειδιών σε Elixir

3 ασκήσεις

Σχετικά με την έννοια Λίστες λέξεων-κλειδιών

Μια λίστα λέξεων-κλειδιών είναι μια λίστα από πλειάδες {key, value}. Υπάρχουν δύο τρόποι για να γράψεις μια λίστα λέξεων-κλειδιών:

# concise
[month: "April", year: 2018]

# explicit
[{:month, "April"}, {:year, 2018}]

Τα κλειδιά πρέπει να είναι άτομα

Δεν είναι κάθε λίστα από πλειάδες 2 στοιχείων λίστα λέξεων-κλειδιών. Τα κλειδιά πρέπει να είναι άτομα:

Keyword.keyword?([{"month", "April"}])
# => false

Αν θέλεις να χρησιμοποιήσεις στο κλειδί χαρακτήρες άλλους εκτός από γράμματα, αριθμούς και _, πρέπει να το περικλείσεις σε εισαγωγικά. Ωστόσο, αυτό δεν το κάνει συμβολοσειρά. Παραμένει άτομο.

Keyword.keyword?(["day of week": "Monday"])
# => true

Τα κλειδιά μπορούν να επαναλαμβάνονται

Τα κλειδιά σε μια λίστα λέξεων-κλειδιών μπορούν να επαναλαμβάνονται και τα ζεύγη κλειδιού-τιμής είναι διατεταγμένα. Όταν προσπαθείς να πάρεις μία μόνο τιμή κάτω από ένα δεδομένο κλειδί, θα πάρεις την πρώτη τιμή και οποιεσδήποτε άλλες τιμές κάτω από το ίδιο κλειδί θα αγνοηθούν σιωπηλά.

list = [month: "April", month: "May"]

Keyword.get_values(list, :month)
# => ["April", "May"]

Keyword.get(list, :month)
# => "April"

Οι λίστες λέξεων-κλειδιών υποστηρίζουν επίσης τη συμπεριφορά Access.

list[:month]
# => "April"

Οι λίστες λέξεων-κλειδιών ως επιλογές

Τα χαρακτηριστικά των λιστών λέξεων-κλειδιών τις έκαναν τον προεπιλεγμένο μηχανισμό για να περνάς επιλογές σε συναρτήσεις στην Elixir.

Όταν έμαθες για το if, είδες μια ειδική συντομότερη σύνταξη:

if age >= 16, do: "beer", else: "no beer"

Αυτό μπορεί να φαίνεται σαν το if να δέχεται δύο ορίσματα, αλλά το ζεύγος do: και else: είναι στην πραγματικότητα ένα μόνο όρισμα, μια λίστα λέξεων-κλειδιών. Ο ίδιος κώδικας θα μπορούσε να γραφτεί ως εξής:

if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]

Η χρήση των λιστών λέξεων-κλειδιών ως επιλογών συνάρτησης είναι τόσο συνηθισμένη που η Elixir σου επιτρέπει να παραλείψεις τις αγκύλες όταν η λίστα λέξεων-κλειδιών είναι το τελευταίο όρισμα που περνάς σε μια συνάρτηση.

Επειδή στην Elixir οι πλειάδες, οι λίστες, οι χάρτες και άλλα αντιμετωπίζονται το ίδιο με τις κλήσεις συναρτήσεων, αυτή η δυνατότητα είναι διαθέσιμη και σε αυτά.

[1, 2, three: 3]
# => [1, 2, {:three, 3}]

Αντιστοίχιση προτύπων

Για να κάνεις επιτυχώς αντιστοίχιση προτύπων σε μια λίστα λέξεων-κλειδιών χρησιμοποιώντας τη σύντομη σύνταξη, θα έπρεπε να ορίσεις όλα τα κλειδιά με τη σωστή σειρά. Αυτό κάνει την αντιστοίχιση προτύπων μια απίθανη επιλογή για να δουλέψεις με λίστες λέξεων-κλειδιών. Χρησιμοποίησε αντ' αυτού το άρθρωμα Keyword ή τη συμπεριφορά Access.

[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]

Λίστες λέξεων-κλειδιών έναντι χαρτών

Λίστα λέξεων-κλειδιών Χάρτης
Τύπος κλειδιού Άτομα Οτιδήποτε, μπορούν να αναμειχθούν σε έναν χάρτη
Διπλότυπα κλειδιά Ναι Όχι
Κλειδιά διατεταγμένα Ναι Όχι
Πρόσβαση list[:key], Keyword.get/2 map.key, map[:key], Map.get/2
Χρόνος πρόσβασης Γραμμικός Λογαριθμικός
Αντιστοίχιση προτύπων Όχι πολύ χρήσιμη Χρήσιμη

Ο ταχύτερος χρόνος πρόσβασης, ο ευέλικτος τύπος κλειδιού και η χρήσιμη αντιστοίχιση προτύπων κάνουν τους χάρτες την προεπιλεγμένη επιλογή στις περισσότερες περιπτώσεις.

Χρησιμοποίησε λίστες λέξεων-κλειδιών όταν δεν έχεις πολλά δεδομένα, αλλά χρειάζεσαι διπλότυπα κλειδιά ή κλειδιά σε συγκεκριμένη σειρά.

Επεξεργασία μέσω GitHub Ο σύνδεσμος ανοίγει σε νέο παράθυρο ή καρτέλα

Μάθε την έννοια Λίστες λέξεων-κλειδιών

Η εξάσκηση είναι κλειδωμένη

Ξεκλείδωσε 1 ακόμη άσκηση για να εξασκηθείς στην έννοια Λίστες λέξεων-κλειδιών