A keyword list nem más, mint {key, value} tuple-ok listája. Kétféleképpen írhatsz keyword listet:
# concise
[month: "April", year: 2018]
# explicit
[{:month, "April"}, {:year, 2018}]
Nem minden 2 elemű tuple-okból álló lista számít keyword listnek. A kulcsoknak atomnak kell lenniük:
Keyword.keyword?([{"month", "April"}])
# => false
Ha a kulcsban a betűktől, a számoktól és a _ karaktertől eltérő karaktereket szeretnél használni, idézőjelek közé kell tenned. Ez azonban nem teszi stringgé: továbbra is atom marad.
Keyword.keyword?(["day of week": "Monday"])
# => true
A keyword listben a kulcsok ismétlődhetnek, és a kulcs-érték párok sorrendje megmarad. Ha egy adott kulcshoz egyetlen értéket próbálsz lekérni, az első értéket kapod meg, a többi, ugyanahhoz a kulcshoz tartozó érték pedig csendben figyelmen kívül marad.
list = [month: "April", month: "May"]
Keyword.get_values(list, :month)
# => ["April", "May"]
Keyword.get(list, :month)
# => "April"
A keyword listek az Access behaviour használatát is támogatják.
list[:month]
# => "April"
A keyword listek tulajdonságai tették őket az Elixirben a függvényeknek átadott opciók alapértelmezett mechanizmusává.
Amikor az if-ről tanultál, találkoztál egy különleges, rövidebb szintaxissal:
if age >= 16, do: "beer", else: "no beer"
Ez úgy tűnhet, mintha az if két argumentumot fogadna el, pedig a do: és az else: valójában egyetlen argumentum, egy keyword list. Ugyanezt a kódot így is leírhatnád:
if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]
A keyword listek használata függvényopcióként annyira gyakori, hogy az Elixir megengedi, hogy elhagyd a szögletes zárójeleket, ha a keyword list a függvény utolsó argumentuma.
Mivel az Elixir szintaxisában a tuple-ok, a listák, a mapek és mások ugyanúgy viselkednek, mint a függvényhívások, ez a lehetőség ezeknél is elérhető.
[1, 2, three: 3]
# => [1, 2, {:three, 3}]
Ha a tömör szintaxissal szeretnél sikeresen mintázatot illeszteni egy keyword listre, az összes kulcsot fel kell sorolnod a megfelelő sorrendben. Ezért a mintázatillesztés nem túl gyakori választás a keyword listek kezelésére. Helyette inkább a Keyword modulra vagy az Access behaviour használatára támaszkodj.
[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
| Keyword list | Map | |
|---|---|---|
| Kulcs típusa | Atomok | Bármi, egy mapben vegyesen is lehet |
| Ismétlődő kulcsok | Igen | Nem |
| A kulcsok sorrendje | Megmarad | Nem számít |
| Elérés |
list[:key], Keyword.get/2
|
map.key, map[:key], Map.get/2
|
| Elérési idő | Lineáris | Logaritmikus |
| Mintázatillesztés | Nem túl hasznos | Hasznos |
A gyorsabb elérés, a rugalmasabb kulcstípus és a hasznosabb mintázatillesztés miatt a legtöbb esetben a map a kézenfekvő választás.
Akkor használj keyword listet, ha nincs sok adatod, de szükséged van ismétlődő kulcsokra vagy meghatározott sorrendű kulcsokra.