قائمة الكلمات المفتاحية هي قائمة من الصفوف بالشكل {key, value}. هناك طريقتان لكتابة قائمة الكلمات المفتاحية:
# concise
[month: "April", year: 2018]
# explicit
[{:month, "April"}, {:year, 2018}]
ليست كل قائمة من الصفوف الثنائية قائمة كلمات مفتاحية. يجب أن تكون المفاتيح ذرات:
Keyword.keyword?([{"month", "April"}])
# => false
إذا أردت استخدام محارف غير الحروف والأرقام و_ في المفتاح، فستحتاج إلى وضعه بين علامتي اقتباس. لكن ذلك لا يجعله سلسلة نصية، فهو لا يزال ذرة.
Keyword.keyword?(["day of week": "Monday"])
# => true
يمكن أن تتكرر المفاتيح في قائمة الكلمات المفتاحية، وأزواج المفتاح والقيمة مرتّبة. عند محاولة الحصول على قيمة واحدة تحت مفتاح معيّن، فستحصل على القيمة الأولى، وأي قيم أخرى تحت المفتاح نفسه ستُتجاهل بصمت.
list = [month: "April", month: "May"]
Keyword.get_values(list, :month)
# => ["April", "May"]
Keyword.get(list, :month)
# => "April"
تدعم قوائم الكلمات المفتاحية أيضًا سلوك الوصول.
list[:month]
# => "April"
جعلت خصائص قوائم الكلمات المفتاحية منها الآلية الافتراضية لتمرير الخيارات إلى الدوال في Elixir.
عند تعلّمك عن if، رأيت صيغة مختصرة خاصة:
if age >= 16, do: "beer", else: "no beer"
قد يبدو هذا وكأن if تقبل وسيطين، لكن الزوجين do: وelse: هما في الحقيقة وسيط واحد، أي قائمة كلمات مفتاحية. ويمكن كتابة الكود نفسه على النحو التالي:
if age >= 16, [do: "beer", else: "no beer"]
# or
if age >= 16, [{:do, "beer"}, {:else, "no beer"}]
استخدام قوائم الكلمات المفتاحية كخيارات للدوال شائع لدرجة أن Elixir تسمح لك بتجاهل الأقواس المربعة عندما تكون قائمة الكلمات المفتاحية آخر وسيط يُمرَّر إلى دالة.
وبما أن الصفوف والقوائم والخرائط وغيرها تُعامَل مثل استدعاءات الدوال في صيغة Elixir، فإن هذه الخاصية متاحة لها أيضًا.
[1, 2, three: 3]
# => [1, 2, {:three, 3}]
لتنجح في مطابقة الأنماط على قائمة كلمات مفتاحية باستخدام الصيغة المختصرة، ستحتاج إلى تحديد كل المفاتيح بالترتيب الصحيح. وهذا يجعل مطابقة الأنماط خيارًا غير مرجّح للتعامل مع قوائم الكلمات المفتاحية. استخدم وحدة Keyword أو سلوك الوصول بدلًا من ذلك.
[month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
[year: year, month: month] = [month: "April", year: 2018]
# => ** (MatchError) no match of right hand side value: [month: "April", year: 2018]
| قائمة الكلمات المفتاحية | خريطة | |
|---|---|---|
| نوع المفتاح | ذرات | أي نوع، ويمكن خلطها في خريطة واحدة |
| مفاتيح مكررة | نعم | لا |
| ترتيب المفاتيح | نعم | لا |
| الوصول |
list[:key], Keyword.get/2
|
map.key, map[:key], Map.get/2
|
| زمن الوصول | خطي | لوغاريتمي |
| مطابقة الأنماط | ليست مفيدة كثيرًا | مفيدة |
زمن وصول أسرع، ونوع مفاتيح مرن، ومطابقة أنماط مفيدة تجعل الخرائط الخيار الافتراضي في معظم الحالات.
استخدم قوائم الكلمات المفتاحية عندما لا تكون لديك بيانات كثيرة، لكنك تحتاج إلى مفاتيح مكررة أو مفاتيح بترتيب معيّن.